cuelang.org/go@v0.13.0/encoding/jsonschema/testdata/external/config.cue (about)

     1  @extern(embed)
     2  
     3  package external
     4  
     5  // TODO use recursive globbing when it's available.
     6  
     7  allTests: _	@embed(glob=tests/*/*.json)
     8  allTests: _	@embed(glob=tests/*/*/*.json)
     9  allTests: _	@embed(glob=tests/*/*/*/*.json)
    10  
    11  allTests: [_]: [... #Schema]
    12  #Schema: {
    13  	description!: string
    14  	comment?: string
    15  	specification?: _
    16  	schema!: _
    17  	tests!: [... #Test]
    18  
    19  	// skip is not part of the orginal test data, but
    20  	// is inserted by our test logic (when CUE_UPDATE=1)
    21  	// to indicate which tests are passing and which
    22  	// are failing. See #Skip for details.
    23  	skip?: #Skip
    24  }
    25  
    26  #Test: {
    27  	description!: string
    28  	comment?: string
    29  	data!: _
    30  	valid!: bool
    31  
    32  	// skip is not part of the orginal test data, but
    33  	// is inserted by our test logic (when CUE_UPDATE=1)
    34  	// to indicate which tests are passing and which
    35  	// are failing. The text indicates some reason as to
    36  	// why the test is skipped.
    37  	skip?: #Skip
    38  }
    39  
    40  // #Skip indicates that a test or schema should be skipped
    41  // in the external test. The text indicates some reason as to
    42  // why the schema is skipped for a given evaluator version.
    43  //
    44  // If all fields are empty, the skip field itself should be omitted.
    45  #Skip: {
    46  	v2?: string
    47  	v3?: string
    48  }