github.com/1aal/kubeblocks@v0.0.0-20231107070852-e1c03e598921/deploy/oracle-mysql/config/oracle-mysql-config-constraint.cue (about)

     1  //Copyright (C) 2022-2023 ApeCloud Co., Ltd
     2  //
     3  //This file is part of KubeBlocks project
     4  //
     5  //This program is free software: you can redistribute it and/or modify
     6  //it under the terms of the GNU Affero General Public License as published by
     7  //the Free Software Foundation, either version 3 of the License, or
     8  //(at your option) any later version.
     9  //
    10  //This program is distributed in the hope that it will be useful
    11  //but WITHOUT ANY WARRANTY; without even the implied warranty of
    12  //MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    13  //GNU Affero General Public License for more details.
    14  //
    15  //You should have received a copy of the GNU Affero General Public License
    16  //along with this program.  If not, see <http://www.gnu.org/licenses/>.
    17  
    18  #MysqlParameter: {
    19  
    20  	// Sets the autocommit mode
    21  	autocommit?: string & "0" | "1" | "OFF" | "ON"
    22  
    23  	open_files_limit: int | *5000
    24  
    25  	// Enables or disables the Performance Schema
    26  	performance_schema: string & "0" | "1" | "OFF" | "ON" | *"0"
    27  
    28  	// Prevents execution of statements that cannot be logged in a transactionally safe manner
    29  	enforce_gtid_consistency?: string & "OFF" | "WARN" | "ON"
    30  
    31  	// The size in bytes of the memory buffer innodb uses to cache data and indexes of its tables
    32  	innodb_buffer_pool_size?: int & >=5242880 & <=18446744073709551615 @k8sResource(quantity)
    33  
    34  	// The number of simultaneous client connections allowed.
    35  	max_connections?: int & >=1 & <=100000
    36  
    37  	// GTID Mode
    38  	gtid_mode?: string & "0" | "OFF" | "ON" | "1"
    39  
    40  	// Each thread that does a sequential scan allocates this buffer. Increased value may help perf if performing many sequential scans.
    41  	read_buffer_size: int & >=8200 & <=2147479552 | *262144
    42  
    43  	// When it is enabled, the server permits no updates except from updates performed by slave threads.
    44  	read_only?: string & "0" | "1" | "{TrueIfReplica}"
    45  
    46  	// Avoids disk reads when reading rows in sorted order following a key-sort operation. Large values can improve ORDER BY perf.
    47  	read_rnd_buffer_size: int & >=8200 & <=2147479552 | *524288
    48  
    49  	// Increase the value of join_buffer_size to get a faster full join when adding indexes is not possible.
    50  	join_buffer_size?: int & >=128 & <=18446744073709547520
    51  
    52  	// Larger value improves perf for ORDER BY or GROUP BY operations.
    53  	sort_buffer_size?: int & >=32768 & <=18446744073709551615
    54  
    55  	// Determines Innodb transaction durability
    56  	innodb_flush_log_at_trx_commit?: int & >=0 & <=2
    57  
    58  	// Sync binlog (MySQL flush to disk or rely on OS)
    59  	sync_binlog: int & >=0 & <=18446744073709547520 | *1
    60  
    61  	// Write a core file if mysqld dies.
    62  	"core-file"?: string & "0" | "1" | "OFF" | "ON"
    63  
    64  	// MySQL data directory
    65  	datadir?: string
    66  
    67  	// The number of the port on which the server listens for TCP/IP connections.
    68  	port?: int
    69  
    70  	// The MySQL installation base directory.
    71  	basedir?: string
    72  
    73  	// (UNIX) socket file and (WINDOWS) named pipe used for local connections.
    74  	socket?: string
    75  
    76  	// The path name of the process ID file. This file is used by other programs such as MySQLd_safe to determine the server's process ID.
    77  	pid_file?: string
    78  
    79  	// other parameters
    80  	// reference mysql parameters
    81  	...
    82  }
    83  
    84  // SectionName is section name
    85  [SectionName=_]: #MysqlParameter