github.com/aergoio/aergo@v1.3.1/libtool/src/gmp-6.1.2/mpn/mips32/mul_1.asm (about)

     1  dnl  MIPS32 mpn_mul_1 -- Multiply a limb vector with a single limb and store
     2  dnl  the product in a second limb vector.
     3  
     4  dnl  Copyright 1992, 1994, 1996, 2000, 2002 Free Software Foundation, Inc.
     5  
     6  dnl  This file is part of the GNU MP Library.
     7  dnl
     8  dnl  The GNU MP Library is free software; you can redistribute it and/or modify
     9  dnl  it under the terms of either:
    10  dnl
    11  dnl    * the GNU Lesser General Public License as published by the Free
    12  dnl      Software Foundation; either version 3 of the License, or (at your
    13  dnl      option) any later version.
    14  dnl
    15  dnl  or
    16  dnl
    17  dnl    * the GNU General Public License as published by the Free Software
    18  dnl      Foundation; either version 2 of the License, or (at your option) any
    19  dnl      later version.
    20  dnl
    21  dnl  or both in parallel, as here.
    22  dnl
    23  dnl  The GNU MP Library is distributed in the hope that it will be useful, but
    24  dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
    25  dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
    26  dnl  for more details.
    27  dnl
    28  dnl  You should have received copies of the GNU General Public License and the
    29  dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
    30  dnl  see https://www.gnu.org/licenses/.
    31  
    32  include(`../config.m4')
    33  
    34  C INPUT PARAMETERS
    35  C res_ptr	$4
    36  C s1_ptr	$5
    37  C size		$6
    38  C s2_limb	$7
    39  
    40  ASM_START()
    41  PROLOGUE(mpn_mul_1)
    42  
    43  C feed-in phase 0
    44  	lw	$8,0($5)
    45  
    46  C feed-in phase 1
    47  	addiu	$5,$5,4
    48  	multu	$8,$7
    49  
    50  	addiu	$6,$6,-1
    51  	beq	$6,$0,$LC0
    52  	 move	$2,$0		C zero cy2
    53  
    54  	addiu	$6,$6,-1
    55  	beq	$6,$0,$LC1
    56  	lw	$8,0($5)	C load new s1 limb as early as possible
    57  
    58  Loop:	mflo	$10
    59  	mfhi	$9
    60  	addiu	$5,$5,4
    61  	addu	$10,$10,$2	C add old carry limb to low product limb
    62  	multu	$8,$7
    63  	lw	$8,0($5)	C load new s1 limb as early as possible
    64  	addiu	$6,$6,-1	C decrement loop counter
    65  	sltu	$2,$10,$2	C carry from previous addition -> $2
    66  	sw	$10,0($4)
    67  	addiu	$4,$4,4
    68  	bne	$6,$0,Loop
    69  	 addu	$2,$9,$2	C add high product limb and carry from addition
    70  
    71  C wind-down phase 1
    72  $LC1:	mflo	$10
    73  	mfhi	$9
    74  	addu	$10,$10,$2
    75  	sltu	$2,$10,$2
    76  	multu	$8,$7
    77  	sw	$10,0($4)
    78  	addiu	$4,$4,4
    79  	addu	$2,$9,$2	C add high product limb and carry from addition
    80  
    81  C wind-down phase 0
    82  $LC0:	mflo	$10
    83  	mfhi	$9
    84  	addu	$10,$10,$2
    85  	sltu	$2,$10,$2
    86  	sw	$10,0($4)
    87  	j	$31
    88  	addu	$2,$9,$2	C add high product limb and carry from addition
    89  EPILOGUE(mpn_mul_1)