github.com/aergoio/aergo@v1.3.1/libtool/src/gmp-6.1.2/mpn/powerpc64/elf.m4 (about)

     1  divert(-1)
     2  dnl  m4 macros for powerpc64 GNU/Linux assembly.
     3  
     4  dnl  Copyright 2003, 2005, 2006 Free Software Foundation, Inc.
     5  
     6  dnl  This file is part of the GNU MP Library.
     7  dnl
     8  dnl  The GNU MP Library is free software; you can redistribute it and/or modify
     9  dnl  it under the terms of either:
    10  dnl
    11  dnl    * the GNU Lesser General Public License as published by the Free
    12  dnl      Software Foundation; either version 3 of the License, or (at your
    13  dnl      option) any later version.
    14  dnl
    15  dnl  or
    16  dnl
    17  dnl    * the GNU General Public License as published by the Free Software
    18  dnl      Foundation; either version 2 of the License, or (at your option) any
    19  dnl      later version.
    20  dnl
    21  dnl  or both in parallel, as here.
    22  dnl
    23  dnl  The GNU MP Library is distributed in the hope that it will be useful, but
    24  dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
    25  dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
    26  dnl  for more details.
    27  dnl
    28  dnl  You should have received copies of the GNU General Public License and the
    29  dnl  GNU Lesser General Public License along with the GNU MP Library.  If not,
    30  dnl  see https://www.gnu.org/licenses/.
    31  
    32  define(`ASM_START',
    33  `ifdef(`ELFv2_ABI',
    34  `
    35  	.abiversion 2
    36  ')')
    37  
    38  dnl  Called: PROLOGUE_cpu(GSYM_PREFIX`'foo[,toc])
    39  dnl          EPILOGUE_cpu(GSYM_PREFIX`'foo)
    40  dnl
    41  
    42  define(`PROLOGUE_cpu',
    43  m4_assert_numargs_range(1,2)
    44  `ifelse(`$2',toc,,
    45  `ifelse(`$2',,,`m4_error(`Unrecognised PROLOGUE parameter')')')dnl
    46  ifdef(`ELFv2_ABI',
    47  `
    48  	.globl	$1
    49  	.type	$1, @function
    50  	.section	".text"
    51  	.align	5
    52  $1:
    53  ifelse(`$2',toc,`
    54  0:	addis	2, 12, (.TOC.-0b)@ha
    55  	addi	2, 2, (.TOC.-0b)@l
    56  	.localentry $1, .-$1
    57  ',)
    58  ',`
    59  	.globl	$1
    60  	.globl	.$1
    61  	.section	".opd","aw"
    62  	.align	3
    63  $1:
    64  	.llong	.$1, .TOC.@tocbase, 0
    65  	.size	$1, 24
    66  	.type	.$1, @function
    67  	.section	".text"
    68  	.align	5
    69  .$1:
    70  ')')
    71  
    72  define(`EPILOGUE_cpu',
    73  m4_assert_numargs(1)
    74  `ifdef(`ELFv2_ABI',`
    75  	.size	$1, .-$1
    76  ',`
    77  	.size	.$1, .-.$1
    78  ')')
    79  
    80  define(`TOC_ENTRY', `')
    81  
    82  define(`LEA',
    83  m4_assert_numargs(2)
    84  `define(`TOC_ENTRY',
    85  `	.section	".toc", "aw"
    86  ..$2:	.tc	$2[TC], $2')'
    87  	`ld	$1, ..$2@toc(2)')
    88  
    89  define(`LEAL',
    90  m4_assert_numargs(2)
    91  `LEA($1,$2)')
    92  
    93  
    94  define(`EXTERN',
    95  m4_assert_numargs(1)
    96  `dnl')
    97  
    98  define(`EXTERN_FUNC',
    99  m4_assert_numargs(1)
   100  `dnl')
   101  
   102  define(`DEF_OBJECT',
   103  m4_assert_numargs_range(1,2)
   104  `
   105  	.section	.rodata
   106  	ALIGN(ifelse($#,1,2,$2))
   107  	.type	$1, @object
   108  $1:
   109  ')
   110  
   111  define(`END_OBJECT',
   112  m4_assert_numargs(1)
   113  `	.size	$1, .-$1')
   114  
   115  define(`CALL',
   116  	`bl	GSYM_PREFIX`'$1
   117  	nop')
   118  
   119  define(`ASM_END', `TOC_ENTRY')
   120  
   121  undefine(`EXTRA_REGISTER')
   122  
   123  divert