github.com/apache/beam/sdks/v2@v2.48.2/java/io/hbase/build.gradle (about)

     1  /*
     2   * Licensed to the Apache Software Foundation (ASF) under one
     3   * or more contributor license agreements.  See the NOTICE file
     4   * distributed with this work for additional information
     5   * regarding copyright ownership.  The ASF licenses this file
     6   * to you under the Apache License, Version 2.0 (the
     7   * License); you may not use this file except in compliance
     8   * with the License.  You may obtain a copy of the License at
     9   *
    10   *     http://www.apache.org/licenses/LICENSE-2.0
    11   *
    12   * Unless required by applicable law or agreed to in writing, software
    13   * distributed under the License is distributed on an AS IS BASIS,
    14   * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
    15   * See the License for the specific language governing permissions and
    16   * limitations under the License.
    17   */
    18  
    19  plugins { id 'org.apache.beam.module' }
    20  applyJavaNature( automaticModuleName: 'org.apache.beam.sdk.io.hbase')
    21  provideIntegrationTestingDependencies()
    22  enableJavaPerformanceTesting()
    23  
    24  
    25  description = "Apache Beam :: SDKs :: Java :: IO :: HBase"
    26  ext.summary = "Library to read and write from/to HBase"
    27  
    28  test {
    29    systemProperty "log4j.configuration", "log4j-test.properties"
    30    jvmArgs "-XX:-UseGCOverheadLimit"
    31    if (System.getProperty("beamSurefireArgline")) {
    32      jvmArgs System.getProperty("beamSurefireArgline")
    33    }
    34    jvmArgs "-Dtest.build.data.basedirectory=build/test-data"
    35  }
    36  
    37  def hbase_version = "1.2.6"
    38  
    39  dependencies {
    40    implementation library.java.vendored_guava_26_0_jre
    41    implementation project(path: ":sdks:java:core", configuration: "shadow")
    42    implementation project(":sdks:java:io:hadoop-common")
    43    implementation library.java.slf4j_api
    44    provided "org.apache.hbase:hbase-shaded-client:$hbase_version"
    45    testImplementation project(path: ":sdks:java:io:common", configuration: "testRuntimeMigration")
    46    testImplementation project(path: ":sdks:java:core", configuration: "shadowTest")
    47    testImplementation library.java.junit
    48    testImplementation library.java.hamcrest
    49    testImplementation library.java.hadoop_minicluster
    50    testImplementation library.java.hadoop_hdfs
    51    testImplementation library.java.hadoop_common
    52    testImplementation "org.apache.hbase:hbase-shaded-server:$hbase_version"
    53    testImplementation("org.apache.hbase:hbase-server:$hbase_version:tests") {
    54      // We prevent bringing in unshaded dependencies to not conflict
    55      // with hbase-shaded-server and hbase-shaded-client
    56      transitive = false
    57    }
    58    testImplementation("org.apache.hbase:hbase-common:$hbase_version:tests") {
    59      // We prevent bringing in unshaded dependencies to not conflict
    60      // with hbase-shaded-server and hbase-shaded-client
    61      transitive = false
    62    }
    63    testImplementation "org.apache.hbase:hbase-hadoop-compat:$hbase_version:tests"
    64    testImplementation "org.apache.hbase:hbase-hadoop2-compat:$hbase_version:tests"
    65    testRuntimeOnly project(path: ":runners:direct-java", configuration: "shadow")
    66  }
    67