github.com/apache/beam/sdks/v2@v2.48.2/java/testing/expansion-service/build.gradle (about)

     1  /*
     2   * Licensed to the Apache Software Foundation (ASF) under one
     3   * or more contributor license agreements.  See the NOTICE file
     4   * distributed with this work for additional information
     5   * regarding copyright ownership.  The ASF licenses this file
     6   * to you under the Apache License, Version 2.0 (the
     7   * License); you may not use this file except in compliance
     8   * with the License.  You may obtain a copy of the License at
     9   *
    10   *     http://www.apache.org/licenses/LICENSE-2.0
    11   *
    12   * Unless required by applicable law or agreed to in writing, software
    13   * distributed under the License is distributed on an AS IS BASIS,
    14   * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
    15   * See the License for the specific language governing permissions and
    16   * limitations under the License.
    17   */
    18  import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
    19  
    20  plugins { id 'org.apache.beam.module' }
    21  applyJavaNature(
    22    publish: false,
    23    automaticModuleName: 'org.apache.beam.sdk.testing.expansion',
    24  )
    25  
    26  description = "Apache Beam :: SDKs :: Java :: Test Expansion Service"
    27  ext.summary = """Testing Expansion Service used for executing cross-language transform tests."""
    28  
    29  
    30  dependencies {
    31    testImplementation project(path: ":sdks:java:core", configuration: "shadow")
    32    testImplementation project(":sdks:java:io:parquet")
    33    testImplementation project(":sdks:java:expansion-service")
    34    testImplementation project(path: ":sdks:java:extensions:avro", configuration: "testRuntimeMigration")
    35    testRuntimeOnly project(":sdks:java:extensions:google-cloud-platform-core")
    36    testRuntimeOnly library.java.hadoop_client
    37  }
    38  
    39  task runTestExpansionService (type: JavaExec) {
    40    mainClass = "org.apache.beam.sdk.expansion.service.ExpansionService"
    41    classpath = sourceSets.test.runtimeClasspath
    42    args = [project.findProperty("constructionService.port") ?: "8097"]
    43  }
    44  
    45  task buildTestExpansionServiceJar(type: ShadowJar) {
    46    archiveAppendix = "testExpansionService"
    47    // Use zip64 mode to avoid "Archive contains more than 65535 entries".
    48    zip64 = true
    49    mergeServiceFiles()
    50    manifest {
    51      attributes(
    52              'Main-Class': 'org.apache.beam.sdk.expansion.service.ExpansionService'
    53      )
    54    }
    55    exclude "META-INF/INDEX.LIST"
    56    exclude "META-INF/*.SF"
    57    exclude "META-INF/*.DSA"
    58    exclude "META-INF/*.RSA"
    59    configurations = [
    60      project.configurations.testRuntimeClasspath
    61    ]
    62    from sourceSets.main.output
    63    from sourceSets.test.output
    64  }