github.com/apache/beam/sdks/v2@v2.48.2/java/testing/kafka-service/build.gradle (about)

     1  /*
     2   * Licensed to the Apache Software Foundation (ASF) under one
     3   * or more contributor license agreements.  See the NOTICE file
     4   * distributed with this work for additional information
     5   * regarding copyright ownership.  The ASF licenses this file
     6   * to you under the Apache License, Version 2.0 (the
     7   * License); you may not use this file except in compliance
     8   * with the License.  You may obtain a copy of the License at
     9   *
    10   *     http://www.apache.org/licenses/LICENSE-2.0
    11   *
    12   * Unless required by applicable law or agreed to in writing, software
    13   * distributed under the License is distributed on an AS IS BASIS,
    14   * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
    15   * See the License for the specific language governing permissions and
    16   * limitations under the License.
    17   */
    18  import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
    19  
    20  plugins { id 'org.apache.beam.module' }
    21  applyJavaNature(
    22    publish: false,
    23    automaticModuleName: 'org.apache.beam.sdk.testing.kafka')
    24  
    25  description = "Apache Beam :: SDKs :: Java :: Test Kafka Service"
    26  ext.summary = """Self-contained Kafka service for testing IO transforms."""
    27  
    28  
    29  dependencies {
    30    testImplementation library.java.kafka
    31    testImplementation "org.apache.zookeeper:zookeeper:3.5.6"
    32    testRuntimeOnly library.java.slf4j_log4j12
    33  }
    34  
    35  task runTestKafkaService (type: JavaExec) {
    36    mainClass = "org.apache.beam.sdk.testing.kafka.LocalKafka"
    37    classpath = sourceSets.test.runtimeClasspath
    38    args = [
    39      project.findProperty("kafka.port") ?: "9092",
    40      project.findProperty("zookeeper.port") ?: "2181"
    41    ]
    42  }
    43  
    44  task buildTestKafkaServiceJar(type: ShadowJar) {
    45    archiveAppendix = "testKafkaService"
    46    // Use zip64 mode to avoid "Archive contains more than 65535 entries".
    47    zip64 = true
    48    mergeServiceFiles()
    49    manifest {
    50      attributes(
    51              'Main-Class': 'org.apache.beam.sdk.testing.kafka.LocalKafka'
    52      )
    53    }
    54    exclude "META-INF/INDEX.LIST"
    55    exclude "META-INF/*.SF"
    56    exclude "META-INF/*.DSA"
    57    exclude "META-INF/*.RSA"
    58    configurations = [
    59      project.configurations.testRuntimeClasspath
    60    ]
    61    from sourceSets.main.output
    62    from sourceSets.test.output
    63  }