github.com/code-reading/golang@v0.0.0-20220303082512-ba5bc0e589a3/go/src/syscall/asm9_unix2_amd64.s (about)

     1  // Copyright 2016 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build dragonfly || freebsd
     6  // +build dragonfly freebsd
     7  
     8  #include "textflag.h"
     9  #include "funcdata.h"
    10  
    11  //
    12  // Syscall9 support for AMD64, DragonFly and FreeBSD
    13  //
    14  
    15  // func Syscall9(trap int64, a1, a2, a3, a4, a5, a6, a7, a8, a9 int64) (r1, r2, err int64);
    16  TEXT	·Syscall9(SB),NOSPLIT,$0-104
    17  	CALL	runtime·entersyscall(SB)
    18  	MOVQ	num+0(FP), AX	// syscall entry
    19  	MOVQ	a1+8(FP), DI
    20  	MOVQ	a2+16(FP), SI
    21  	MOVQ	a3+24(FP), DX
    22  	MOVQ	a4+32(FP), R10
    23  	MOVQ	a5+40(FP), R8
    24  	MOVQ	a6+48(FP), R9
    25  
    26  	// shift around the last three arguments so they're at the
    27  	// top of the stack when the syscall is called.
    28  	// note that we are scribbling over the Go arguments now.
    29  	MOVQ	SP, CX	// hide (SP) writes from vet
    30  	MOVQ	a7+56(FP), R11 // arg 7
    31  	MOVQ	R11, 8(CX)
    32  	MOVQ	a8+64(FP), R11 // arg 8
    33  	MOVQ	R11, 16(CX)
    34  	MOVQ	a9+72(FP), R11 // arg 9
    35  	MOVQ	R11, 24(CX)
    36  
    37  	SYSCALL
    38  	JCC	ok9
    39  	MOVQ	$-1, r1+80(FP)	// r1
    40  	MOVQ	$0, r2+88(FP)	// r2
    41  	MOVQ	AX, err+96(FP)	// errno
    42  	CALL	runtime·exitsyscall(SB)
    43  	RET
    44  ok9:
    45  	MOVQ	AX, r1+80(FP)	// r1
    46  	MOVQ	DX, r2+88(FP)	// r2
    47  	MOVQ	$0, err+96(FP)	// errno
    48  	CALL	runtime·exitsyscall(SB)
    49  	RET