github.com/discordapp/buildkite-agent@v2.6.6+incompatible/templates/1.0-beta.1-6/bootstrap.bat (about)

     1  @echo off
     2  
     3  REM echo --- Environment Variables
     4  REM SET
     5  
     6  echo --- Creating Build Environment
     7  
     8  REM Returns the location of this file
     9  
    10  SET BUILDBOX_DIR=%~dp0
    11  
    12  REM Add the BUILDBOX_DIR to the PATH
    13  
    14  SET PATH=%PATH%;%BUILDBOX_DIR%
    15  
    16  REM Create the build directory
    17  
    18  SET SANITIED_PROJECT_SLUG=%BUILDBOX_PROJECT_SLUG:/=\%
    19  SET BUILDBOX_BUILD_DIR=%BUILDBOX_DIR%%BUILDBOX_AGENT_NAME%\%SANITIED_PROJECT_SLUG%
    20  
    21  IF NOT EXIST %BUILDBOX_BUILD_DIR% (
    22    REM Create the build directory
    23  
    24    ECHO ^> MKDIR %BUILDBOX_BUILD_DIR%
    25    MKDIR %BUILDBOX_BUILD_DIR%
    26    IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    27  )
    28  
    29  REM Move to the build directory
    30  
    31  ECHO ^> CD %BUILDBOX_BUILD_DIR%
    32  CD %BUILDBOX_BUILD_DIR%
    33  IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    34  
    35  REM Do we need to do a git checkout?
    36  
    37  IF NOT EXIST ".git" (
    38    ECHO ^> git clone %BUILDBOX_REPO%
    39    CALL git clone "%BUILDBOX_REPO%" . -v
    40    IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    41  )
    42  
    43  REM Clean the repo
    44  
    45  ECHO ^> git clean -fdq
    46  CALL git clean -fdq
    47  IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    48  
    49  REM Fetch the latest code
    50  
    51  ECHO ^> git fetch -q
    52  CALL git fetch -q
    53  IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    54  
    55  REM Only reset to the branch if we're not on a tag
    56  
    57  IF "%BUILDBOX_TAG%" == "" (
    58    ECHO ^> git reset --hard origin/%BUILDBOX_BRANCH%
    59    CALL git reset --hard origin/%BUILDBOX_BRANCH%
    60    IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    61  )
    62  
    63  ECHO ^> git checkout -qf "%BUILDBOX_COMMIT%"
    64  CALL git checkout -qf "%BUILDBOX_COMMIT%"
    65  IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    66  
    67  ECHO --- Running Build Script
    68  
    69  IF "%BUILDBOX_SCRIPT_PATH%" == "" (
    70    echo ERROR: No script path has been set for this project. Please go to \"Project Settings\" and add the path to your build script
    71    exit 1
    72  ) ELSE (
    73    ECHO ^> CALL %BUILDBOX_SCRIPT_PATH%
    74    CALL %BUILDBOX_SCRIPT_PATH%
    75    SET EXIT_STATUS=%ERRORLEVEL%
    76  )
    77  
    78  IF NOT "%BUILDBOX_ARTIFACT_PATHS%" == "" (
    79    REM If you want to upload artifacts to your own server, uncomment the lines below
    80    REM and replace the AWS_ACCESS_KEY_ID, AWS_SECRET_ACCESS_KEY with keys to your
    81    REM own bucket.
    82    REM
    83    REM SET AWS_SECRET_ACCESS_KEY=yyy
    84    REM SET AWS_ACCESS_KEY_ID=xxx
    85    REM SET AWS_S3_ACL=private
    86    REM call buildbox-agent build-artifact upload "%BUILDBOX_ARTIFACT_PATHS%" "s3://name-of-your-s3-bucket/%BUILDBOX_JOB_ID%"
    87  
    88    REM Show the output of the artifact uploder when in debug mode
    89    IF "%BUILDBOX_AGENT_DEBUG%" == "true" (
    90      ECHO --- Uploading Artifacts
    91      ECHO ^> %BUILDBOX_DIR%\buildbox-agent artifact upload "%BUILDBOX_ARTIFACT_PATHS%"
    92      call %BUILDBOX_DIR%\buildbox-agent build-artifact upload "%BUILDBOX_ARTIFACT_PATHS%"
    93      IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    94    ) ELSE (
    95      call %BUILDBOX_DIR%\buildbox-agent build-artifact upload "%BUILDBOX_ARTIFACT_PATHS%" > nul 2>&1
    96      IF %ERRORLEVEL% NEQ 0 EXIT %ERRORLEVEL%
    97    )
    98  )
    99  
   100  EXIT %EXIT_STATUS%