github.com/elopio/cli@v6.21.2-0.20160902224010-ea909d1fdb2f+incompatible/installers/windows/windows-installer-x64.iss (about)

     1  [Setup]
     2  ChangesEnvironment=yes
     3  AppName=Cloud Foundry CLI
     4  AppVersion=VERSION
     5  AppVerName=Cloud Foundry CLI version VERSION
     6  AppPublisher=Cloud Foundry Foundation
     7  SignTool=signtool sign /f $qSIGNTOOL_CERT_PATH$q /p $qSIGNTOOL_CERT_PASSWORD$q /t http://timestamp.comodoca.com/authenticode $f
     8  ArchitecturesInstallIn64BitMode=x64 ia64
     9  ArchitecturesAllowed=x64 ia64
    10  PrivilegesRequired=none
    11  DefaultDirName={pf}\CloudFoundry
    12  
    13  [Registry]
    14  Root: HKLM; Subkey: "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"; ValueType: expandsz; ValueName: "Path"; ValueData: "{olddata};{app}"; Check: IsAdminLoggedOn and Uninstall32Bit() and NeedsAddPath(ExpandConstant('{app}'))
    15  Root: HKCU; Subkey: "Environment"; ValueType: expandsz; ValueName: "Path"; ValueData: "{olddata};{app}"; Check: not IsAdminLoggedOn and Uninstall32Bit() and NeedsAddPath(ExpandConstant('{app}'))
    16  
    17  [Files]
    18  Source: CF_SOURCE; DestDir: "{app}"
    19  
    20  [Code]
    21  function Uninstall32Bit(): Boolean;
    22  var
    23    resultCode: Integer;
    24    uninstallString: String;
    25    uninstallStringPath: String;
    26  begin
    27    uninstallString := '';
    28    uninstallStringPath := 'SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Cloud Foundry CLI_is1';
    29    RegQueryStringValue(HKLM, uninstallStringPath, 'UninstallString', uninstallString);
    30  
    31    if uninstallString <> '' then
    32    begin
    33      uninstallString := RemoveQuotes(uninstallString);
    34      Exec(uninstallString, '/VERYSILENT /SUPPRESSMSGBOXES /NORESTART','', SW_HIDE, ewWaitUntilTerminated, resultCode)
    35    end;
    36    Result := true;
    37  end;
    38  
    39  #include "common.iss"