github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/certificate_authorities_file_ownership.rego (about)

     1  # METADATA
     2  # title: "Ensure that the client certificate authorities file ownership is set to root:root"
     3  # description: "Ensure that the certificate authorities file ownership is set to root:root."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0076
    11  #   avd_id: AVD-KCV-0076
    12  #   severity: CRITICAL
    13  #   short_code: ensure-certificate_authorities-ownership-set-root:root
    14  #   recommended_action: "Change the certificate authorities file ownership to root:root"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0076
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  validate_certificate_authorities_ownership(sp) := {"certificateAuthoritiesFileOwnership": violation} {
    25  	sp.kind == "NodeInfo"
    26  	sp.type == types[_]
    27  	violation := {ownership | ownership = sp.info.certificateAuthoritiesFileOwnership.values[_]; not ownership == "root:root"}
    28  	count(violation) > 0
    29  }
    30  
    31  deny[res] {
    32  	output := validate_certificate_authorities_ownership(input)
    33  	msg := "Ensure that the certificate authorities file ownership is set to root:root."
    34  	res := result.new(msg, output)
    35  }