github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/kubelet_anonymous_auth_argument.rego (about)

     1  # METADATA
     2  # title: "Ensure that the --anonymous-auth argument is set to false"
     3  # description: "Disable anonymous requests to the Kubelet server."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0079
    11  #   avd_id: AVD-KCV-0079
    12  #   severity: CRITICAL
    13  #   short_code: disable-anonymous-requests-kubelet-server.
    14  #   recommended_action: "Disable anonymous requests to the Kubelet server"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0079
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  validate_kubelet_anonymous_auth_set(sp) := {"kubeletAnonymousAuthArgumentSet": violation} {
    25  	sp.kind == "NodeInfo"
    26  	sp.type == types[_]
    27  	violation := {anonymous_auth | anonymous_auth = sp.info.kubeletAnonymousAuthArgumentSet.values[_]; anonymous_auth == "true"}
    28  	count(violation) > 0
    29  }
    30  
    31  deny[res] {
    32  	output := validate_kubelet_anonymous_auth_set(input)
    33  	msg := "Ensure that the --anonymous-auth argument is set to false"
    34  	res := result.new(msg, output)
    35  }