github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/kubelet_only_use_strong_cryptographic.rego (about)

     1  # METADATA
     2  # title: "Ensure that the Kubelet only makes use of Strong Cryptographic Ciphers"
     3  # description: "Ensure that the Kubelet is configured to only use strong cryptographic ciphers."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0092
    11  #   avd_id: AVD-KCV-0092
    12  #   severity: CRITICAL
    13  #   short_code: ensure-Kubelet-only-makes-use-strong-cryptographic-ciphers
    14  #   recommended_action: "If using a Kubelet config file, edit the file to set TLSCipherSuites"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0092
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  strong_cryptographic := [
    25  	"TLS_ECDHE_ECDSA_WITH_AES_128_GCM_SHA256",
    26  	"TLS_ECDHE_RSA_WITH_AES_128_GCM_SHA256",
    27  	"TLS_ECDHE_ECDSA_WITH_CHACHA20_POLY1305",
    28  	"TLS_ECDHE_RSA_WITH_AES_256_GCM_SHA384",
    29  	"TLS_ECDHE_RSA_WITH_CHACHA20_POLY1305",
    30  	"TLS_ECDHE_ECDSA_WITH_AES_256_GCM_SHA384",
    31  	"TLS_RSA_WITH_AES_256_GCM_SHA384",
    32  	"TLS_RSA_WITH_AES_128_GCM_SHA256",
    33  ]
    34  
    35  validate_kubelet_only_use_strong_cryptographic(sp) := {"kubeletOnlyUseStrongCryptographic": only_use_strong_cryptographic} {
    36  	sp.kind == "NodeInfo"
    37  	sp.type == types[_]
    38  	only_use_strong_cryptographic := sp.info.kubeletOnlyUseStrongCryptographic.values[_]
    39  	not contains(strong_cryptographic, only_use_strong_cryptographic)
    40  }
    41  
    42  contains(cryptographic, elem) {
    43  	cryptographic[_] = elem
    44  }
    45  
    46  validate_kubelet_only_use_strong_cryptographic(sp) := {"kubeletOnlyUseStrongCryptographic": only_use_strong_cryptographic} {
    47  	sp.kind == "NodeInfo"
    48  	sp.type == types[_]
    49  	count(sp.info.kubeletOnlyUseStrongCryptographic.values) == 0
    50  	only_use_strong_cryptographic = {}
    51  }
    52  
    53  deny[res] {
    54  	output := validate_kubelet_only_use_strong_cryptographic(input)
    55  	msg := "Ensure that the Kubelet only makes use of Strong Cryptographic Ciphers"
    56  	res := result.new(msg, output)
    57  }