github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/kubelet_rotate_kubelet_server_certificate.rego (about)

     1  # METADATA
     2  # title: "Verify that the RotateKubeletServerCertificate argument is set to true"
     3  # description: "Enable kubelet server certificate rotation."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0091
    11  #   avd_id: AVD-KCV-0091
    12  #   severity: HIGH
    13  #   short_code: ensure-rotate-kubelet-server-certificate-argument-set-true
    14  #   recommended_action: "Edit the kubelet service file /etc/kubernetes/kubelet.conf and set --feature-gates=RotateKubeletServerCertificate=true"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0091
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  validate_kubelet_rotate_kubelet_server_certificate(sp) := {"kubeletRotateKubeletServerCertificateArgumentSet": violation} {
    25  	sp.kind == "NodeInfo"
    26  	sp.type == types[_]
    27  	violation := {rotate_kubelet_server_certificate | rotate_kubelet_server_certificate = sp.info.kubeletRotateKubeletServerCertificateArgumentSet.values[_]; rotate_kubelet_server_certificate == "false"}
    28  	count(violation) > 0
    29  }
    30  
    31  validate_kubelet_rotate_kubelet_server_certificate(sp) := {"kubeletRotateKubeletServerCertificateArgumentSet": rotate_kubelet_server_certificate} {
    32  	sp.kind == "NodeInfo"
    33  	sp.type == types[_]
    34  	count(sp.info.kubeletRotateKubeletServerCertificateArgumentSet.values) == 0
    35  	rotate_kubelet_server_certificate = {}
    36  }
    37  
    38  deny[res] {
    39  	output := validate_kubelet_rotate_kubelet_server_certificate(input)
    40  	msg := "Verify that the RotateKubeletServerCertificate argument is set to true"
    41  	res := result.new(msg, output)
    42  }