github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/kubelet_tls_key_file.rego (about)

     1  # METADATA
     2  # title: "Ensure that the --tls-key-file argument are set as appropriate"
     3  # description: "Setup TLS connection on the Kubelets."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0089
    11  #   avd_id: AVD-KCV-0089
    12  #   severity: CRITICAL
    13  #   short_code: ensure-tls-key-file-argument-set-appropriate
    14  #   recommended_action: "If using a Kubelet config file, edit the file to set tlskeyFile to the location"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0089
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  validate_kubelet_tls_key_file(sp) := {"kubeletTlsPrivateKeyFileArgumentSet": violation} {
    25  	sp.kind == "NodeInfo"
    26  	sp.type == types[_]
    27  	violation := {tls_key_file | tls_key_file = sp.info.kubeletTlsPrivateKeyFileArgumentSet.values[_]; not endswith(tls_key_file, ".key")}
    28  	count(violation) > 0
    29  }
    30  
    31  validate_kubelet_tls_key_file(sp) := {"kubeletTlsPrivateKeyFileArgumentSet": tls_key_file} {
    32  	sp.kind == "NodeInfo"
    33  	sp.type == types[_]
    34  	count(sp.info.kubeletTlsPrivateKeyFileArgumentSet.values) == 0
    35  	tls_key_file := {}
    36  }
    37  
    38  deny[res] {
    39  	output := validate_kubelet_tls_key_file(input)
    40  	msg := "Ensure that the --tls-key-file argument are set as appropriate"
    41  	res := result.new(msg, output)
    42  }