github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/cisbenchmarks/kubelet/kublet_service_file_permission.rego (about)

     1  # METADATA
     2  # title: "Ensure that the kubelet service file permissions are set to 600 or more restrictive"
     3  # description: "Ensure that the kubelet service file has permissions of 600 or more restrictive."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://www.cisecurity.org/benchmark/kubernetes
     9  # custom:
    10  #   id: KCV0069
    11  #   avd_id: AVD-KCV-0069
    12  #   severity: HIGH
    13  #   short_code: ensure-kubelet-service-file-permissions-set-600-or-more-restrictive
    14  #   recommended_action: "Change the kubelet service file /etc/systemd/system/kubelet.service.d/10-kubeadm.conf permissions of 600 or more restrictive "
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KCV0069
    19  
    20  import data.lib.kubernetes
    21  
    22  types := ["master", "worker"]
    23  
    24  validate_service_file_permission(sp) := {"kubeletServiceFilePermissions": violation} {
    25  	sp.kind == "NodeInfo"
    26  	sp.type == types[_]
    27  	violation := {permission | permission = sp.info.kubeletServiceFilePermissions.values[_]; permission > 600}
    28  	count(violation) > 0
    29  }
    30  
    31  deny[res] {
    32  	output := validate_service_file_permission(input)
    33  	msg := "Ensure that the kubelet service file permissions are set to 600 or more restrictive"
    34  	res := result.new(msg, output)
    35  }