github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/CPU_not_limited.rego (about)

     1  # METADATA
     2  # title: "CPU not limited"
     3  # description: "Enforcing CPU limits prevents DoS via resource exhaustion."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://cloud.google.com/blog/products/containers-kubernetes/kubernetes-best-practices-resource-requests-and-limits
     9  # custom:
    10  #   id: KSV011
    11  #   avd_id: AVD-KSV-0011
    12  #   severity: LOW
    13  #   short_code: limit-cpu
    14  #   recommended_action: "Set a limit value under 'containers[].resources.limits.cpu'."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV011
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  default failLimitsCPU = false
    24  
    25  # getLimitsCPUContainers returns all containers which have set resources.limits.cpu
    26  getLimitsCPUContainers[container] {
    27  	container := kubernetes.containers[_]
    28  	utils.has_key(container.resources.limits, "cpu")
    29  }
    30  
    31  # getNoLimitsCPUContainers returns all containers which have not set
    32  # resources.limits.cpu
    33  getNoLimitsCPUContainers[container] {
    34  	container := kubernetes.containers[_]
    35  	not getLimitsCPUContainers[container]
    36  }
    37  
    38  deny[res] {
    39  	output := getNoLimitsCPUContainers[_]
    40  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should set 'resources.limits.cpu'", [output.name, kubernetes.kind, kubernetes.name]))
    41  	res := result.new(msg, output)
    42  }