github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/SYS_ADMIN_capability.rego (about)

     1  # METADATA
     2  # title: "SYS_ADMIN capability added"
     3  # description: "SYS_ADMIN gives the processes running inside the container privileges that are equivalent to root."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubesec.io/basics/containers-securitycontext-capabilities-add-index-sys-admin/
     9  # custom:
    10  #   id: KSV005
    11  #   avd_id: AVD-KSV-0005
    12  #   severity: HIGH
    13  #   short_code: no-sysadmin-capability
    14  #   recommended_action: "Remove the SYS_ADMIN capability from 'containers[].securityContext.capabilities.add'."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV005
    19  
    20  import data.lib.kubernetes
    21  
    22  default failCapsSysAdmin = false
    23  
    24  # getCapsSysAdmin returns the names of all containers which include
    25  # 'SYS_ADMIN' in securityContext.capabilities.add.
    26  getCapsSysAdmin[container] {
    27  	container := kubernetes.containers[_]
    28  	container.securityContext.capabilities.add[_] == "SYS_ADMIN"
    29  }
    30  
    31  deny[res] {
    32  	output := getCapsSysAdmin[_]
    33  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should not include 'SYS_ADMIN' in 'securityContext.capabilities.add'", [output.name, kubernetes.kind, kubernetes.name]))
    34  	res := result.new(msg, output)
    35  }