github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/delete_pod_logs.rego (about)

     1  # METADATA
     2  # title: "Delete pod logs"
     3  # description: "Used to cover attacker’s tracks, but most clusters ship logs quickly off-cluster."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV042
    11  #   avd_id: AVD-KSV-0042
    12  #   severity: MEDIUM
    13  #   short_code: no-delete-pod-logs
    14  #   recommended_action: "Remove verbs 'delete' and 'deletecollection' for resource 'pods/log' for Role and ClusterRole"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV042
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["delete", "deletecollection", "*"]
    24  
    25  readKinds := ["Role", "ClusterRole"]
    26  
    27  deletePodsLogRestricted[input.rules[ru]] {
    28  	some ru, r, v
    29  	input.kind == readKinds[_]
    30  	input.rules[ru].resources[r] == "pods/log"
    31  	input.rules[ru].verbs[v] == readVerbs[_]
    32  }
    33  
    34  deny[res] {
    35  	badRule := deletePodsLogRestricted[_]
    36  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resource 'pods/log' for verbs %s", [kubernetes.kind, kubernetes.name, readVerbs]))
    37  	res := result.new(msg, badRule)
    38  }