github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/get_shell_on_pod.rego (about)

     1  # METADATA
     2  # title: "Exec into Pods"
     3  # description: "Check whether role permits getting shell on pods"
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV053
    11  #   avd_id: AVD-KSV-0053
    12  #   severity: HIGH
    13  #   short_code: no-getting-shell-pods
    14  #   recommended_action: "Create a role which does not permit getting shell on pods"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV053
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  workloads := ["pods/exec"]
    24  
    25  changeVerbs := ["create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    26  
    27  readKinds := ["Role", "ClusterRole"]
    28  
    29  execPodsRestricted[input.rules[ru]] {
    30  	some ru, r, v
    31  	input.kind == readKinds[_]
    32  	input.rules[ru].resources[r] == workloads[_]
    33  	input.rules[ru].verbs[v] == changeVerbs[_]
    34  }
    35  
    36  deny[res] {
    37  	badRule := execPodsRestricted[_]
    38  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resource '%s' for verbs %s", [kubernetes.kind, kubernetes.name, workloads, changeVerbs]))
    39  	res := result.new(msg, badRule)
    40  }