github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/impersonate_privileged_groups.rego (about)

     1  # METADATA
     2  # title: "Do not allow impersonation of privileged groups"
     3  # description: "Check whether role permits impersonating privileged groups"
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV043
    11  #   avd_id: AVD-KSV-0043
    12  #   severity: CRITICAL
    13  #   short_code: no-impersonate-privileged-groups
    14  #   recommended_action: "Create a role which does not permit to impersonate privileged groups if not needed"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV043
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readKinds := ["Role", "ClusterRole"]
    24  
    25  impersonatePrivilegedGroups[input.rules[ru]] {
    26  	some ru
    27  	input.kind == readKinds[_]
    28  	input.rules[ru].apiGroups[_] == "*"
    29  	input.rules[ru].resources[_] == "groups"
    30  	input.rules[ru].verbs[_] == "impersonate"
    31  }
    32  
    33  deny[res] {
    34  	badRule := impersonatePrivilegedGroups[_]
    35  	msg := "Role permits impersonation of privileged groups"
    36  	res := result.new(msg, badRule)
    37  }