github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_all_resources_at_namespace.rego (about)

     1  # METADATA
     2  # title: "Manage all resources at the namespace"
     3  # description: "Full control of the resources within a namespace.  In some cluster configurations, this is excessive. In others, this is normal (a gitops deployment operator like flux)"
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV112
    11  #   avd_id: AVD-KSV-0112
    12  #   severity: CRITICAL
    13  #   short_code: no-wildcard-resource-role
    14  #   recommended_actions: "Remove '*' from 'rules.resources'. Provide specific list of resources to be managed by role in namespace"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV112
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["create", "update", "delete", "deletecollection", "impersonate", "*", "list", "get"]
    24  
    25  readKinds := ["Role"]
    26  
    27  managingAllResourcesAtNamespace[input.rules[ru]] {
    28  	some ru, r, v
    29  	input.kind == readKinds[_]
    30  	input.rules[ru].resources[r] == "*"
    31  	input.rules[ru].verbs[v] == readVerbs[_]
    32  }
    33  
    34  deny[res] {
    35  	badRule := managingAllResourcesAtNamespace[_]
    36  	msg := kubernetes.format(sprintf("%s '%s' shouldn't manage all resources at the namespace '%s'", [kubernetes.kind, kubernetes.name, kubernetes.namespace]))
    37  	res := result.new(msg, badRule)
    38  }