github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_eks_iam_auth_configmap.rego (about)

     1  # METADATA
     2  # title: "Manage EKS IAM Auth ConfigMap"
     3  # description: "Ability to add AWS IAM to RBAC bindings via special EKS configmap."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV115
    11  #   avd_id: AVD-KSV-0115
    12  #   severity: CRITICAL
    13  #   short_code: eks-iam-configmap
    14  #   recommended_actions: "Remove write permission verbs for resource 'configmaps' named 'aws-auth'"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV115
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    24  
    25  readKinds := ["Role", "ClusterRole"]
    26  
    27  readResource = "configmaps"
    28  
    29  resourceName := "aws-auth"
    30  
    31  manageEKSIAMAuthConfigmap[input.rules[ru]] {
    32  	some ru, r, v
    33  	input.kind == readKinds[_]
    34  	input.rules[ru].resources[r] == readResource
    35  	input.rules[ru].verbs[v] == readVerbs[_]
    36  	input.rules[ru].resourceNames[rn] == resourceName
    37  }
    38  
    39  deny[res] {
    40  	badRule := manageEKSIAMAuthConfigmap[_]
    41  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resource '%s' named '%s' for verbs %s", [kubernetes.kind, kubernetes.name, readResource, resourceName, readVerbs]))
    42  	res := result.new(msg, badRule)
    43  }