github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_kubernetes_networking.rego (about)

     1  # METADATA
     2  # title: "Manage Kubernetes networking"
     3  # description: "The ability to control which pods get service traffic directed to them allows for interception attacks. Controlling network policy allows for bypassing lateral movement restrictions."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV056
    11  #   avd_id: AVD-KSV-0056
    12  #   severity: HIGH
    13  #   short_code: no-manage-networking-resources
    14  #   recommended_action: "Networking resources are only allowed for verbs 'list', 'watch', 'get'"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV056
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readKinds := ["Role", "ClusterRole"]
    24  
    25  readVerbs := ["create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    26  
    27  readResources := ["services", "endpoints", "endpointslices", "networkpolicies", "ingresses"]
    28  
    29  managekubernetesNetworking[input.rules[ru]] {
    30  	some ru, r, v
    31  	input.kind == readKinds[_]
    32  	input.rules[ru].resources[r] == readResources[_]
    33  	input.rules[ru].verbs[v] == readVerbs[_]
    34  }
    35  
    36  deny[res] {
    37  	badRule := managekubernetesNetworking[_]
    38  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resources %s for verbs %s", [kubernetes.kind, kubernetes.name, readResources, readVerbs]))
    39  	res := result.new(msg, badRule)
    40  }