github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_kubernetes_rbac_resources.rego (about)

     1  # METADATA
     2  # title: "Manage Kubernetes RBAC resources"
     3  # description: "An effective level of access equivalent to cluster-admin should not be provided."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV050
    11  #   avd_id: AVD-KSV-0050
    12  #   severity: CRITICAL
    13  #   short_code: no-manage-rbac-resources
    14  #   recommended_action: "Remove write permission verbs for resource 'roles' and 'rolebindings'"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV050
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["create", "update", "delete", "deletecollection", "impersonate", "*"]
    24  
    25  readKinds := ["Role", "ClusterRole"]
    26  
    27  readResources := ["roles", "rolebindings"]
    28  
    29  manageK8sRBACResources[input.rules[ru]] {
    30  	some ru, r, v
    31  	input.kind == readKinds[_]
    32  	input.rules[ru].resources[r] == readResources[_]
    33  	input.rules[ru].verbs[v] == readVerbs[_]
    34  }
    35  
    36  deny[res] {
    37  	badRule := manageK8sRBACResources[_]
    38  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resources %s for verbs %s", [kubernetes.kind, kubernetes.name, readResources, readVerbs]))
    39  	res := result.new(msg, badRule)
    40  }