github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_namespace_secrets.rego (about)

     1  # METADATA
     2  # title: "Manage namespace secrets"
     3  # description: "Viewing secrets at the namespace scope can lead to escalation if another service account in that namespace has a higher privileged rolebinding or clusterrolebinding bound."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV113
    11  #   avd_id: AVD-KSV-0113
    12  #   severity: Medium
    13  #   short_code: no-manage-ns-secrets
    14  #   recommended_actions: "Manage namespace secrets are not allowed. Remove resource 'secrets' from role"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV113
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["get", "list", "watch", "create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    24  
    25  readKinds := ["Role"]
    26  
    27  resourceManageSecret[input.rules[ru]] {
    28  	some ru, r, v
    29  	input.kind == readKinds[_]
    30  	input.rules[ru].resources[r] == "secrets"
    31  	input.rules[ru].verbs[v] == readVerbs[_]
    32  }
    33  
    34  deny[res] {
    35  	badRule := resourceManageSecret[_]
    36  	msg := kubernetes.format(sprintf("%s '%s' shouldn't have access to manage secrets in namespace '%s'", [kubernetes.kind, kubernetes.name, kubernetes.namespace]))
    37  	res := result.new(msg, badRule)
    38  }