github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_secrets.rego (about)

     1  # METADATA
     2  # title: "Manage secrets"
     3  # description: "Viewing secrets at the cluster-scope is akin to cluster-admin in most clusters as there are typically at least one service accounts (their token stored in a secret) bound to cluster-admin directly or a role/clusterrole that gives similar permissions."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV041
    11  #   avd_id: AVD-KSV-0041
    12  #   severity: CRITICAL
    13  #   short_code: no-manage-secrets
    14  #   recommended_actions: "Manage secrets are not allowed. Remove resource 'secrets' from cluster role"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV041
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["get", "list", "watch", "create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    24  
    25  readKinds := ["ClusterRole"]
    26  
    27  resourceManageSecret[input.rules[ru]] {
    28  	some ru, r, v
    29  	input.kind == readKinds[_]
    30  	input.rules[ru].resources[r] == "secrets"
    31  	input.rules[ru].verbs[v] == readVerbs[_]
    32  }
    33  
    34  deny[res] {
    35  	badRule := resourceManageSecret[_]
    36  	msg := kubernetes.format(sprintf("%s '%s' shouldn't have access to manage resource 'secrets'", [kubernetes.kind, kubernetes.name]))
    37  	res := result.new(msg, badRule)
    38  }