github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/manage_webhook_configurations.rego (about)

     1  # METADATA
     2  # title: "Manage webhookconfigurations"
     3  # description: "Webhooks can silently intercept or actively mutate/block resources as they are being created or updated. This includes secrets and pod specs."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV114
    11  #   avd_id: AVD-KSV-0114
    12  #   severity: Critical
    13  #   short_code: no-manage-webhook
    14  #   recommended_actions: "Remove webhook configuration resouces/verbs, acceptable values for verbs ['get', 'list', 'watch']"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV114
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["create", "update", "patch", "delete", "deletecollection", "impersonate", "*"]
    24  
    25  readKinds := ["Role", "ClusterRole"]
    26  
    27  readResource = ["mutatingwebhookconfigurations", "validatingwebhookconfigurations"]
    28  
    29  manageWebhookConfig[input.rules[ru]] {
    30  	some ru, r, v
    31  	input.kind == readKinds[_]
    32  	input.rules[ru].resources[r] == readResource[_]
    33  	input.rules[ru].verbs[v] == readVerbs[_]
    34  }
    35  
    36  deny[res] {
    37  	badRule := manageWebhookConfig[_]
    38  	msg := kubernetes.format(sprintf("%s '%s' should not have access to resources %s for verbs %s", [kubernetes.kind, kubernetes.name, readResource, readVerbs]))
    39  	res := result.new(msg, badRule)
    40  }