github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/memory_not_limited.rego (about)

     1  # METADATA
     2  # title: "Memory not limited"
     3  # description: "Enforcing memory limits prevents DoS via resource exhaustion."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubesec.io/basics/containers-resources-limits-memory/
     9  # custom:
    10  #   id: KSV018
    11  #   avd_id: AVD-KSV-0018
    12  #   severity: LOW
    13  #   short_code: limit-memory
    14  #   recommended_action: "Set a limit value under 'containers[].resources.limits.memory'."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV018
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  default failLimitsMemory = false
    24  
    25  # getLimitsMemoryContainers returns all containers which have set resources.limits.memory
    26  getLimitsMemoryContainers[container] {
    27  	container := kubernetes.containers[_]
    28  	utils.has_key(container.resources.limits, "memory")
    29  }
    30  
    31  # getNoLimitsMemoryContainers returns all containers which have not set
    32  # resources.limits.memory
    33  getNoLimitsMemoryContainers[container] {
    34  	container := kubernetes.containers[_]
    35  	not getLimitsMemoryContainers[container]
    36  }
    37  
    38  deny[res] {
    39  	output := getNoLimitsMemoryContainers[_]
    40  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should set 'resources.limits.memory'", [output.name, kubernetes.kind, kubernetes.name]))
    41  	res := result.new(msg, output)
    42  }