github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/general/privilege_escalation_from_node_proxy.rego (about)

     1  # METADATA
     2  # title: "Do not allow privilege escalation from node proxy"
     3  # description: "Check whether role permits privilege escalation from node proxy"
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/rbac-good-practices/
     9  # custom:
    10  #   id: KSV047
    11  #   avd_id: AVD-KSV-0047
    12  #   severity: HIGH
    13  #   short_code: no-privilege-escalation-from-node-proxy
    14  #   recommended_action: "Create a role which does not permit privilege escalation from node proxy"
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV047
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  readVerbs := ["get", "create"]
    24  
    25  readKinds := ["Role", "ClusterRole"]
    26  
    27  privilegeEscalationFromNodeProxy[input.rules[ru]] {
    28  	input.kind == readKinds[_]
    29  	some ru, r, v
    30  	input.rules[ru].resources[r] == "nodes/proxy"
    31  	input.rules[ru].verbs[v] == readVerbs[_]
    32  }
    33  
    34  deny[res] {
    35  	badRule := privilegeEscalationFromNodeProxy[_]
    36  	msg := "Role permits privilege escalation from node proxy"
    37  	res := result.new(msg, badRule)
    38  }