github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/pss/baseline/2_privileged.rego (about)

     1  # METADATA
     2  # title: "Privileged"
     3  # description: "Privileged containers share namespaces with the host system and do not offer any security. They should be used exclusively for system containers that require high privileges."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/pod-security-standards/#baseline
     9  # custom:
    10  #   id: KSV017
    11  #   avd_id: AVD-KSV-0017
    12  #   severity: HIGH
    13  #   short_code: no-privileged-containers
    14  #   recommended_action: "Change 'containers[].securityContext.privileged' to 'false'."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV017
    19  
    20  import data.lib.kubernetes
    21  
    22  default failPrivileged = false
    23  
    24  # getPrivilegedContainers returns all containers which have
    25  # securityContext.privileged set to true.
    26  getPrivilegedContainers[container] {
    27  	container := kubernetes.containers[_]
    28  	container.securityContext.privileged == true
    29  }
    30  
    31  deny[res] {
    32  	output := getPrivilegedContainers[_]
    33  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should set 'securityContext.privileged' to false", [output.name, kubernetes.kind, kubernetes.name]))
    34  	res := result.new(msg, output)
    35  }