github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/pss/baseline/6_apparmor_policy_disabled.rego (about)

     1  # METADATA
     2  # title: "Runtime/Default AppArmor profile not set"
     3  # description: "A program inside the container can bypass AppArmor protection policies."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/pod-security-standards/#baseline
     9  # custom:
    10  #   id: KSV002
    11  #   avd_id: AVD-KSV-0002
    12  #   severity: MEDIUM
    13  #   short_code: use-default-apparmor-profile
    14  #   recommended_action: "Remove 'container.apparmor.security.beta.kubernetes.io' annotation or set it to 'runtime/default'."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV002
    19  
    20  import data.lib.kubernetes
    21  
    22  default failAppArmor = false
    23  
    24  apparmor_keys[container] = key {
    25  	container := kubernetes.containers[_]
    26  	key := sprintf("%s/%s", ["container.apparmor.security.beta.kubernetes.io", container.name])
    27  }
    28  
    29  custom_apparmor_containers[container] {
    30  	key := apparmor_keys[container]
    31  	annotations := kubernetes.annotations[_]
    32  	val := annotations[key]
    33  	val != "runtime/default"
    34  }
    35  
    36  deny[res] {
    37  	output := custom_apparmor_containers[_]
    38  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should specify an AppArmor profile", [output.name, kubernetes.kind, kubernetes.name]))
    39  	res := result.new(msg, output)
    40  }