github.com/khulnasoft-lab/defsec@v1.0.5-0.20230827010352-5e9f46893d95/rules/kubernetes/policies/pss/restricted/3_runs_as_root.rego (about)

     1  # METADATA
     2  # title: "Runs as root user"
     3  # description: "'runAsNonRoot' forces the running image to run as a non-root user to ensure least privileges."
     4  # scope: package
     5  # schemas:
     6  # - input: schema["kubernetes"]
     7  # related_resources:
     8  # - https://kubernetes.io/docs/concepts/security/pod-security-standards/#restricted
     9  # custom:
    10  #   id: KSV012
    11  #   avd_id: AVD-KSV-0012
    12  #   severity: MEDIUM
    13  #   short_code: no-root
    14  #   recommended_action: "Set 'containers[].securityContext.runAsNonRoot' to true."
    15  #   input:
    16  #     selector:
    17  #     - type: kubernetes
    18  package builtin.kubernetes.KSV012
    19  
    20  import data.lib.kubernetes
    21  import data.lib.utils
    22  
    23  default checkRunAsNonRoot = false
    24  
    25  # getNonRootContainers returns the names of all containers which have
    26  # securityContext.runAsNonRoot set to true.
    27  getNonRootContainers[container] {
    28  	allContainers := kubernetes.containers[_]
    29  	allContainers.securityContext.runAsNonRoot == true
    30  	container := allContainers.name
    31  }
    32  
    33  # getRootContainers returns the names of all containers which have
    34  # securityContext.runAsNonRoot set to false or not set.
    35  getRootContainers[container] {
    36  	container := kubernetes.containers[_]
    37  	not getNonRootContainers[container.name]
    38  }
    39  
    40  # checkRunAsNonRoot is true if securityContext.runAsNonRoot is set to false
    41  # or if securityContext.runAsNonRoot is not set.
    42  checkRunAsNonRootContainers {
    43  	count(getRootContainers) > 0
    44  }
    45  
    46  checkRunAsNonRootPod {
    47  	allPods := kubernetes.pods[_]
    48  	not allPods.spec.securityContext.runAsNonRoot
    49  }
    50  
    51  deny[res] {
    52  	checkRunAsNonRootPod
    53  	output := getRootContainers[_]
    54  	msg := kubernetes.format(sprintf("Container '%s' of %s '%s' should set 'securityContext.runAsNonRoot' to true", [output.name, kubernetes.kind, kubernetes.name]))
    55  	res := result.new(msg, output)
    56  }