github.com/lzhfromustc/gofuzz@v0.0.0-20211116160056-151b3108bbd1/runtime/memclr_386.s (about)

     1  // Copyright 2014 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  // +build !plan9
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  
    10  // NOTE: Windows externalthreadhandler expects memclr to preserve DX.
    11  
    12  // See memclrNoHeapPointers Go doc for important implementation constraints.
    13  
    14  // func memclrNoHeapPointers(ptr unsafe.Pointer, n uintptr)
    15  TEXT runtime·memclrNoHeapPointers(SB), NOSPLIT, $0-8
    16  	MOVL	ptr+0(FP), DI
    17  	MOVL	n+4(FP), BX
    18  	XORL	AX, AX
    19  
    20  	// MOVOU seems always faster than REP STOSL.
    21  tail:
    22  	// BSR+branch table make almost all memmove/memclr benchmarks worse. Not worth doing.
    23  	TESTL	BX, BX
    24  	JEQ	_0
    25  	CMPL	BX, $2
    26  	JBE	_1or2
    27  	CMPL	BX, $4
    28  	JB	_3
    29  	JE	_4
    30  	CMPL	BX, $8
    31  	JBE	_5through8
    32  	CMPL	BX, $16
    33  	JBE	_9through16
    34  	CMPB	internal∕cpu·X86+const_offsetX86HasSSE2(SB), $1
    35  	JNE	nosse2
    36  	PXOR	X0, X0
    37  	CMPL	BX, $32
    38  	JBE	_17through32
    39  	CMPL	BX, $64
    40  	JBE	_33through64
    41  	CMPL	BX, $128
    42  	JBE	_65through128
    43  	CMPL	BX, $256
    44  	JBE	_129through256
    45  
    46  loop:
    47  	MOVOU	X0, 0(DI)
    48  	MOVOU	X0, 16(DI)
    49  	MOVOU	X0, 32(DI)
    50  	MOVOU	X0, 48(DI)
    51  	MOVOU	X0, 64(DI)
    52  	MOVOU	X0, 80(DI)
    53  	MOVOU	X0, 96(DI)
    54  	MOVOU	X0, 112(DI)
    55  	MOVOU	X0, 128(DI)
    56  	MOVOU	X0, 144(DI)
    57  	MOVOU	X0, 160(DI)
    58  	MOVOU	X0, 176(DI)
    59  	MOVOU	X0, 192(DI)
    60  	MOVOU	X0, 208(DI)
    61  	MOVOU	X0, 224(DI)
    62  	MOVOU	X0, 240(DI)
    63  	SUBL	$256, BX
    64  	ADDL	$256, DI
    65  	CMPL	BX, $256
    66  	JAE	loop
    67  	JMP	tail
    68  
    69  _1or2:
    70  	MOVB	AX, (DI)
    71  	MOVB	AX, -1(DI)(BX*1)
    72  	RET
    73  _0:
    74  	RET
    75  _3:
    76  	MOVW	AX, (DI)
    77  	MOVB	AX, 2(DI)
    78  	RET
    79  _4:
    80  	// We need a separate case for 4 to make sure we clear pointers atomically.
    81  	MOVL	AX, (DI)
    82  	RET
    83  _5through8:
    84  	MOVL	AX, (DI)
    85  	MOVL	AX, -4(DI)(BX*1)
    86  	RET
    87  _9through16:
    88  	MOVL	AX, (DI)
    89  	MOVL	AX, 4(DI)
    90  	MOVL	AX, -8(DI)(BX*1)
    91  	MOVL	AX, -4(DI)(BX*1)
    92  	RET
    93  _17through32:
    94  	MOVOU	X0, (DI)
    95  	MOVOU	X0, -16(DI)(BX*1)
    96  	RET
    97  _33through64:
    98  	MOVOU	X0, (DI)
    99  	MOVOU	X0, 16(DI)
   100  	MOVOU	X0, -32(DI)(BX*1)
   101  	MOVOU	X0, -16(DI)(BX*1)
   102  	RET
   103  _65through128:
   104  	MOVOU	X0, (DI)
   105  	MOVOU	X0, 16(DI)
   106  	MOVOU	X0, 32(DI)
   107  	MOVOU	X0, 48(DI)
   108  	MOVOU	X0, -64(DI)(BX*1)
   109  	MOVOU	X0, -48(DI)(BX*1)
   110  	MOVOU	X0, -32(DI)(BX*1)
   111  	MOVOU	X0, -16(DI)(BX*1)
   112  	RET
   113  _129through256:
   114  	MOVOU	X0, (DI)
   115  	MOVOU	X0, 16(DI)
   116  	MOVOU	X0, 32(DI)
   117  	MOVOU	X0, 48(DI)
   118  	MOVOU	X0, 64(DI)
   119  	MOVOU	X0, 80(DI)
   120  	MOVOU	X0, 96(DI)
   121  	MOVOU	X0, 112(DI)
   122  	MOVOU	X0, -128(DI)(BX*1)
   123  	MOVOU	X0, -112(DI)(BX*1)
   124  	MOVOU	X0, -96(DI)(BX*1)
   125  	MOVOU	X0, -80(DI)(BX*1)
   126  	MOVOU	X0, -64(DI)(BX*1)
   127  	MOVOU	X0, -48(DI)(BX*1)
   128  	MOVOU	X0, -32(DI)(BX*1)
   129  	MOVOU	X0, -16(DI)(BX*1)
   130  	RET
   131  nosse2:
   132  	MOVL	BX, CX
   133  	SHRL	$2, CX
   134  	REP
   135  	STOSL
   136  	ANDL	$3, BX
   137  	JNE	tail
   138  	RET