github.com/oam-dev/kubevela@v1.9.11/vela-templates/definitions/deprecated/deploy2runtime.cue (about)

     1  import (
     2  	"vela/op"
     3  )
     4  
     5  "deploy2runtime": {
     6  	type: "workflow-step"
     7  	annotations: {}
     8  	labels: {
     9  		"ui-hidden":  "true"
    10  		"deprecated": "true"
    11  		"scope":      "Application"
    12  	}
    13  	description: "Deploy application to runtime clusters"
    14  }
    15  template: {
    16  	app: op.#Steps & {
    17  		load: op.#Load
    18  		clusters: [...string]
    19  		if parameter.clusters == _|_ {
    20  			listClusters: op.#ListClusters
    21  			clusters:     listClusters.outputs.clusters
    22  		}
    23  		if parameter.clusters != _|_ {
    24  			clusters: parameter.clusters
    25  		}
    26  
    27  		apply: op.#Steps & {
    28  			for _, cluster_ in clusters {
    29  				for name, c in load.value {
    30  					"\(cluster_)-\(name)": op.#ApplyComponent & {
    31  						value:   c
    32  						cluster: cluster_
    33  					}
    34  				}
    35  			}
    36  		}
    37  	}
    38  
    39  	parameter: {
    40  		// +usage=Declare the runtime clusters to apply, if empty, all runtime clusters will be used
    41  		clusters?: [...string]
    42  	}
    43  }