github.com/oam-dev/kubevela@v1.9.11/vela-templates/definitions/registry/kustomize.cue (about)

     1  kustomize: {
     2  	type: "component"
     3  	annotations: {}
     4  	labels: {}
     5  	description: "kustomize can fetching, building, updating and applying Kustomize manifests from git repo."
     6  	attributes: workload: type: "autodetects.core.oam.dev"
     7  }
     8  template: {
     9  	output: {
    10  		apiVersion: "source.toolkit.fluxcd.io/v1beta1"
    11  		kind:       "GitRepository"
    12  		metadata: name: context.name
    13  		spec: {
    14  			interval: parameter.pullInterval
    15  			url:      parameter.repoUrl
    16  			ref: branch: parameter.branch
    17  		}
    18  	}
    19  	outputs: kustomize: {
    20  		apiVersion: "kustomize.toolkit.fluxcd.io/v1beta1"
    21  		kind:       "Kustomization"
    22  		metadata: name: context.name
    23  		spec: {
    24  			interval: parameter.pullInterval
    25  			sourceRef: {
    26  				kind: "GitRepository"
    27  				name: context.name
    28  			}
    29  			path:       parameter.path
    30  			prune:      true
    31  			validation: "client"
    32  		}
    33  	}
    34  
    35  	parameter: {
    36  		//+usage=The repository URL, can be a HTTP/S or SSH address.
    37  		repoUrl: string
    38  
    39  		//+usage=The interval at which to check for repository updates.
    40  		pullInterval: *"1m" | string
    41  
    42  		//+usage=The Git reference to checkout and monitor for changes, defaults to master branch.
    43  		branch: *"master" | string
    44  
    45  		//+usage=Path to the directory containing the kustomization.yaml file, or the set of plain YAMLs a kustomization.yaml should be generated for.
    46  		path: string
    47  	}
    48  }