github.com/shindo/goofys@v0.24.1-0.20210326210429-9e930f0b2d5c/bench/bench_graph_cached.gnuplot (about)

     1  #!/usr/bin/gnuplot
     2  
     3  reset
     4  #fontsize = 12
     5  set terminal pngcairo crop size 1000,640
     6  set output "bench/bench.png"
     7  
     8  #set key at graph 0.24, 0.8 horizontal samplen 0.1
     9  
    10  set key at graph 0.0, 0.8 horizontal samplen 0.1
    11  
    12  set style data histogram
    13  set style histogram errorbars gap 2 lw 1
    14  set style fill solid 1.00 border 0
    15  set boxwidth 0.8
    16  set xtic rotate
    17  unset ytics
    18  set y2tics rotate by 90
    19  
    20  #set yrange [0:100];
    21  
    22  set y2label 'Time (seconds)' offset -2.5
    23  set xlabel ' '
    24  set size 1, 1
    25  
    26  set label 1 'goofys' at graph -0.75, 0.8 left rotate by 90
    27  set label 2 's3fs' at graph -0.45, 0.8 left rotate by 90
    28  set label 3 'riofs' at graph -0.13, 0.8 left rotate by 90
    29  
    30  set lmargin at screen 0.1
    31  
    32  set datafile separator "\t"
    33  
    34  set multiplot #layout 1,3
    35  set bmargin at screen 0.4
    36  #set size 1, 1
    37  
    38  set origin 0.0,0.1
    39  set size 0.3,0.8
    40  set xrange [-0.5:0.8]
    41  
    42  plot 'bench/bench.data' using 2:3:4 title " ", \
    43       '' using 5:6:7 title " ", \
    44       '' using 8:9:10 title " ", \
    45       '' using 0:(0):xticlabel(1) w l title ''
    46  
    47  set key off
    48  unset label 1
    49  unset label 2
    50  unset label 3
    51  set lmargin
    52  
    53  set origin 0.3,0.1
    54  set size 0.2,0.8
    55  set xrange [0.5:1.8]
    56  
    57  plot 'bench/bench.data' using 2:3:4 title " ", \
    58       '' using 5:6:7 title " ", \
    59       '' using 8:9:10 title " ", \
    60       '' using 0:(0):xticlabel(1) w l title ''
    61  
    62  set origin 0.5,0.1
    63  set size 0.2,0.8
    64  set xrange [1.5:2.8]
    65  set yrange [0:0.1]
    66  
    67  plot 'bench/bench.data' using 2:3:4 title " ", \
    68       '' using 5:6:7 title " ", \
    69       '' using 8:9:10 title " ", \
    70       '' using 0:(0):xticlabel(1) w l title ''
    71  
    72  unset multiplot