github.com/status-im/status-go@v1.1.0/nix/overlay.nix (about)

     1  # Override some packages and utilities in 'pkgs'
     2  # and make them available globally via callPackage.
     3  #
     4  # For more details see:
     5  # - https://nixos.wiki/wiki/Overlays
     6  # - https://nixos.org/nixos/nix-pills/callpackage-design-pattern.html
     7  final: prev:
     8  let
     9    inherit (prev) callPackage;
    10  in rec {
    11    androidPkgs = prev.androidenv.composeAndroidPackages {
    12      toolsVersion = "26.1.1";
    13      platformToolsVersion = "33.0.3";
    14      buildToolsVersions = [ "31.0.0" ];
    15      platformVersions = [ "31" ];
    16      cmakeVersions = [ "3.18.1" ];
    17      ndkVersion = "22.1.7171670";
    18      includeNDK = true;
    19      includeExtras = [
    20        "extras;android;m2repository"
    21        "extras;google;m2repository"
    22      ];
    23    };
    24  
    25    go = prev.go_1_21;
    26    buildGoModule = prev.buildGo121Module;
    27    buildGoPackage = prev.buildGo121Package;
    28  
    29    golangci-lint = prev.golangci-lint.override {
    30      buildGoModule = args: prev.buildGo121Module ( args // rec {
    31        version = "1.54.0";
    32        src = prev.fetchFromGitHub {
    33          owner = "golangci";
    34          repo = "golangci-lint";
    35          rev = "v${version}";
    36          hash = "sha256-UXN5gN1SNv3uvBCliJQ+5PSGHRL7RyU6pmZtGUTFsrQ=";
    37        };
    38        vendorHash = "sha256-jUlK/A0HxBrIby2C0zYFtnxQX1bgKVyypI3QdH4u/rg=";
    39      });
    40    };
    41  
    42    go-junit-report = prev.go-junit-report.overrideAttrs ( attrs : rec {
    43      version = "2.1.0";
    44      src = prev.fetchFromGitHub {
    45       owner = "jstemmer";
    46       repo = "go-junit-report";
    47       rev = "v${version}";
    48       sha256 = "sha256-s4XVjACmpd10C5k+P3vtcS/aWxI6UkSUPyxzLhD2vRI=";
    49      };
    50    });
    51  
    52    # Custom packages
    53    go-modvendor = callPackage ./pkgs/go-modvendor { };
    54    cc-test-reporter = callPackage ./pkgs/cc-test-reporter { };
    55    codecov-cli = callPackage ./pkgs/codecov-cli { };
    56  
    57    gomobile = (prev.gomobile.overrideAttrs (old: {
    58      patches = [
    59        (final.fetchurl { # https://github.com/golang/mobile/pull/84
    60          url = "https://github.com/golang/mobile/commit/f20e966e05b8f7e06bed500fa0da81cf6ebca307.patch";
    61          sha256 = "sha256-TZ/Yhe8gMRQUZFAs9G5/cf2b9QGtTHRSObBFD5Pbh7Y=";
    62        })
    63        (final.fetchurl { # https://github.com/golang/go/issues/58426
    64          url = "https://github.com/golang/mobile/commit/406ed3a7b8e44dc32844953647b49696d8847d51.patch";
    65          sha256 = "sha256-dqbYukHkQEw8npOkKykOAzMC3ot/Y4DEuh7fE+ptlr8=";
    66        })
    67        (final.fetchurl { # https://github.com/golang/go/issues/63141
    68          url = "https://github.com/golang/mobile/commit/e2f452493d570cfe278e63eccec99e62d4c775e5.patch";
    69          sha256 = "sha256-gFcy/Ikh7MzmDx5Tpxe3qCnP36+ZTKU2XkJGH6n5l7Q=";
    70        })
    71      ];
    72    }));
    73  }