github.com/swisspost/terratest@v0.0.0-20230214120104-7ec6de2e1ae0/examples/azure/terraform-azure-servicebus-example/outputs.tf (about)

     1  output "resource_group" {
     2    description = "The resource group name of the Service Bus namespace."
     3    value       = azurerm_resource_group.servicebus_rg.name
     4  }
     5  
     6  output "namespace_name" {
     7    description = "The namespace name."
     8    value       = azurerm_servicebus_namespace.servicebus.name
     9  }
    10  
    11  output "namespace_id" {
    12    description = "The namespace ID."
    13    value       = azurerm_servicebus_namespace.servicebus.id
    14    sensitive   = true
    15  }
    16  
    17  output "namespace_authorization_rules" {
    18    description = "List of namespace authorization rules."
    19    value = {
    20      for auth in azurerm_servicebus_namespace_authorization_rule.sbnamespaceauth :
    21      auth.name => {
    22        listen = auth.listen
    23        send   = auth.send
    24        manage = auth.manage
    25      }
    26    }
    27    sensitive = true
    28  }
    29  
    30  output "service_bus_namespace_default_primary_key" {
    31    description = "The primary access key for the authorization rule RootManageSharedAccessKey which is created automatically by Azure."
    32    value       = azurerm_servicebus_namespace.servicebus.default_primary_key
    33    sensitive   = true
    34  }
    35  
    36  output "service_bus_namespace_default_connection_string" {
    37    description = "The primary connection string for the authorization rule RootManageSharedAccessKey which is created automatically by Azure."
    38    value       = azurerm_servicebus_namespace.servicebus.default_primary_connection_string
    39    sensitive   = true
    40  }
    41  
    42  
    43  output "topics" {
    44    description = "All topics with the corresponding subscriptions"
    45    value = {
    46      for topic in azurerm_servicebus_topic.sptopic :
    47      topic.name => {
    48        id   = topic.id
    49        name = topic.name
    50        authorization_rules = {
    51          for auth in azurerm_servicebus_topic_authorization_rule.topicaauth :
    52          auth.name => {
    53            listen = auth.listen
    54            send   = auth.send
    55            manage = auth.manage
    56          } if topic.name == auth.topic_name
    57        }
    58        subscriptions = {
    59          for subscription in azurerm_servicebus_subscription.subscription :
    60          subscription.name => {
    61            name = subscription.name
    62          } if topic.name == subscription.topic_name
    63        }
    64      }
    65    }
    66  }