github.com/tinygo-org/tinygo@v0.31.3-0.20240404173401-90b0bf646c27/targets/nxpmk66f18.ld (about)

     1  
     2  /* Unused, but here to silence a linker warning. */
     3  ENTRY(Reset_Handler)
     4  
     5  /* define memory layout */
     6  MEMORY
     7  {
     8      FLASH_TEXT (rx) : ORIGIN = 0x00000000, LENGTH = 1024K
     9      RAM (rwx)       : ORIGIN = 0x1FFF0000, LENGTH = 256K
    10  }
    11  
    12  _stack_size = 2K;
    13  
    14  /* define output sections */
    15  SECTIONS
    16  {
    17      /* Program code and read-only data goes to FLASH_TEXT. */
    18      .text :
    19      {
    20          /* vector table MUST start at 0x0 */
    21          . = 0;
    22          KEEP(*(.isr_vector))
    23  
    24          /* flash configuration MUST be at 0x400 */
    25          . = 0x400;
    26          KEEP(*(.flash_config))
    27  
    28          /* everything else */
    29          *(.text)
    30          *(.text.*)
    31          *(.rodata)
    32          *(.rodata.*)
    33          . = ALIGN(4);
    34  
    35      } >FLASH_TEXT = 0xFF
    36  }
    37  
    38  INCLUDE "targets/arm.ld"