github.com/twelsh-aw/go/src@v0.0.0-20230516233729-a56fe86a7c81/runtime/internal/syscall/asm_linux_mipsx.s (about)

     1  // Copyright 2022 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build linux && (mips || mipsle)
     6  
     7  #include "textflag.h"
     8  
     9  // func Syscall6(num, a1, a2, a3, a4, a5, a6 uintptr) (r1, r2, errno uintptr)
    10  //
    11  // The 5th and 6th arg go at sp+16, sp+20.
    12  // Note that frame size of 20 means that 24 bytes gets reserved on stack.
    13  TEXT ·Syscall6(SB),NOSPLIT,$20-40
    14  	MOVW	num+0(FP), R2	// syscall entry
    15  	MOVW	a1+4(FP), R4
    16  	MOVW	a2+8(FP), R5
    17  	MOVW	a3+12(FP), R6
    18  	MOVW	a4+16(FP), R7
    19  	MOVW	a5+20(FP), R8
    20  	MOVW	a6+24(FP), R9
    21  	MOVW	R8, 16(R29)
    22  	MOVW	R9, 20(R29)
    23  	MOVW	R0, R3	// reset R3 to 0 as 1-ret SYSCALL keeps it
    24  	SYSCALL
    25  	BEQ	R7, ok
    26  	MOVW	$-1, R1
    27  	MOVW	R1, r1+28(FP)
    28  	MOVW	R0, r2+32(FP)
    29  	MOVW	R2, errno+36(FP)
    30  	RET
    31  ok:
    32  	MOVW	R2, r1+28(FP)
    33  	MOVW	R3, r2+32(FP)
    34  	MOVW	R0, errno+36(FP)
    35  	RET