github.com/vieux/docker@v0.6.3-0.20161004191708-e097c2a938c7/contrib/completion/zsh/_docker (about)

     1  #compdef docker dockerd
     2  #
     3  # zsh completion for docker (http://docker.com)
     4  #
     5  # version:  0.3.0
     6  # github:   https://github.com/felixr/docker-zsh-completion
     7  #
     8  # contributors:
     9  #   - Felix Riedel
    10  #   - Steve Durrheimer
    11  #   - Vincent Bernat
    12  #
    13  # license:
    14  #
    15  # Copyright (c) 2013, Felix Riedel
    16  # All rights reserved.
    17  #
    18  # Redistribution and use in source and binary forms, with or without
    19  # modification, are permitted provided that the following conditions are met:
    20  #     * Redistributions of source code must retain the above copyright
    21  #       notice, this list of conditions and the following disclaimer.
    22  #     * Redistributions in binary form must reproduce the above copyright
    23  #       notice, this list of conditions and the following disclaimer in the
    24  #       documentation and/or other materials provided with the distribution.
    25  #     * Neither the name of the <organization> nor the
    26  #       names of its contributors may be used to endorse or promote products
    27  #       derived from this software without specific prior written permission.
    28  #
    29  # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
    30  # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
    31  # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
    32  # DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> BE LIABLE FOR ANY
    33  # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
    34  # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
    35  # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
    36  # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
    37  # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
    38  # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
    39  #
    40  
    41  # Short-option stacking can be enabled with:
    42  #  zstyle ':completion:*:*:docker:*' option-stacking yes
    43  #  zstyle ':completion:*:*:docker-*:*' option-stacking yes
    44  __docker_arguments() {
    45      if zstyle -t ":completion:${curcontext}:" option-stacking; then
    46          print -- -s
    47      fi
    48  }
    49  
    50  __docker_get_containers() {
    51      [[ $PREFIX = -* ]] && return 1
    52      integer ret=1
    53      local kind type line s
    54      declare -a running stopped lines args names
    55  
    56      kind=$1; shift
    57      type=$1; shift
    58      [[ $kind = (stopped|all) ]] && args=($args -a)
    59  
    60      lines=(${(f)"$(_call_program commands docker $docker_options ps --format 'table' --no-trunc $args)"})
    61  
    62      # Parse header line to find columns
    63      local i=1 j=1 k header=${lines[1]}
    64      declare -A begin end
    65      while (( j < ${#header} - 1 )); do
    66          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
    67          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
    68          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
    69          begin[${header[$i,$((j-1))]}]=$i
    70          end[${header[$i,$((j-1))]}]=$k
    71      done
    72      end[${header[$i,$((j-1))]}]=-1 # Last column, should go to the end of the line
    73      lines=(${lines[2,-1]})
    74  
    75      # Container ID
    76      if [[ $type = (ids|all) ]]; then
    77          for line in $lines; do
    78              s="${${line[${begin[CONTAINER ID]},${end[CONTAINER ID]}]%% ##}[0,12]}"
    79              s="$s:${(l:15:: :::)${${line[${begin[CREATED]},${end[CREATED]}]/ ago/}%% ##}}"
    80              s="$s, ${${${line[${begin[IMAGE]},${end[IMAGE]}]}/:/\\:}%% ##}"
    81              if [[ ${line[${begin[STATUS]},${end[STATUS]}]} = Exit* ]]; then
    82                  stopped=($stopped $s)
    83              else
    84                  running=($running $s)
    85              fi
    86          done
    87      fi
    88  
    89      # Names: we only display the one without slash. All other names
    90      # are generated and may clutter the completion. However, with
    91      # Swarm, all names may be prefixed by the swarm node name.
    92      if [[ $type = (names|all) ]]; then
    93          for line in $lines; do
    94              names=(${(ps:,:)${${line[${begin[NAMES]},${end[NAMES]}]}%% *}})
    95              # First step: find a common prefix and strip it (swarm node case)
    96              (( ${#${(u)names%%/*}} == 1 )) && names=${names#${names[1]%%/*}/}
    97              # Second step: only keep the first name without a /
    98              s=${${names:#*/*}[1]}
    99              # If no name, well give up.
   100              (( $#s != 0 )) || continue
   101              s="$s:${(l:15:: :::)${${line[${begin[CREATED]},${end[CREATED]}]/ ago/}%% ##}}"
   102              s="$s, ${${${line[${begin[IMAGE]},${end[IMAGE]}]}/:/\\:}%% ##}"
   103              if [[ ${line[${begin[STATUS]},${end[STATUS]}]} = Exit* ]]; then
   104                  stopped=($stopped $s)
   105              else
   106                  running=($running $s)
   107              fi
   108          done
   109      fi
   110  
   111      [[ $kind = (running|all) ]] && _describe -t containers-running "running containers" running "$@" && ret=0
   112      [[ $kind = (stopped|all) ]] && _describe -t containers-stopped "stopped containers" stopped "$@" && ret=0
   113      return ret
   114  }
   115  
   116  __docker_stoppedcontainers() {
   117      [[ $PREFIX = -* ]] && return 1
   118      __docker_get_containers stopped all "$@"
   119  }
   120  
   121  __docker_runningcontainers() {
   122      [[ $PREFIX = -* ]] && return 1
   123      __docker_get_containers running all "$@"
   124  }
   125  
   126  __docker_containers() {
   127      [[ $PREFIX = -* ]] && return 1
   128      __docker_get_containers all all "$@"
   129  }
   130  
   131  __docker_containers_ids() {
   132      [[ $PREFIX = -* ]] && return 1
   133      __docker_get_containers all ids "$@"
   134  }
   135  
   136  __docker_containers_names() {
   137      [[ $PREFIX = -* ]] && return 1
   138      __docker_get_containers all names "$@"
   139  }
   140  
   141  __docker_complete_info_plugins() {
   142      [[ $PREFIX = -* ]] && return 1
   143      integer ret=1
   144      emulate -L zsh
   145      setopt extendedglob
   146      local -a plugins
   147      plugins=(${(ps: :)${(M)${(f)${${"$(_call_program commands docker $docker_options info)"##*$'\n'Plugins:}%%$'\n'^ *}}:# $1: *}## $1: })
   148      _describe -t plugins "$1 plugins" plugins && ret=0
   149      return ret
   150  }
   151  
   152  __docker_images() {
   153      [[ $PREFIX = -* ]] && return 1
   154      integer ret=1
   155      declare -a images
   156      images=(${${${(f)"$(_call_program commands docker $docker_options images)"}[2,-1]}/(#b)([^ ]##) ##([^ ]##) ##([^ ]##)*/${match[3]}:${(r:15:: :::)match[2]} in ${match[1]}})
   157      _describe -t docker-images "images" images && ret=0
   158      __docker_repositories_with_tags && ret=0
   159      return ret
   160  }
   161  
   162  __docker_repositories() {
   163      [[ $PREFIX = -* ]] && return 1
   164      declare -a repos
   165      repos=(${${${(f)"$(_call_program commands docker $docker_options images)"}%% *}[2,-1]})
   166      repos=(${repos#<none>})
   167      _describe -t docker-repos "repositories" repos
   168  }
   169  
   170  __docker_repositories_with_tags() {
   171      [[ $PREFIX = -* ]] && return 1
   172      integer ret=1
   173      declare -a repos onlyrepos matched
   174      declare m
   175      repos=(${${${${(f)"$(_call_program commands docker $docker_options images)"}[2,-1]}/ ##/:::}%% *})
   176      repos=(${${repos%:::<none>}#<none>})
   177      # Check if we have a prefix-match for the current prefix.
   178      onlyrepos=(${repos%::*})
   179      for m in $onlyrepos; do
   180          [[ ${PREFIX##${~~m}} != ${PREFIX} ]] && {
   181              # Yes, complete with tags
   182              repos=(${${repos/:::/:}/:/\\:})
   183              _describe -t docker-repos-with-tags "repositories with tags" repos && ret=0
   184              return ret
   185          }
   186      done
   187      # No, only complete repositories
   188      onlyrepos=(${${repos%:::*}/:/\\:})
   189      _describe -t docker-repos "repositories" onlyrepos -qS : && ret=0
   190  
   191      return ret
   192  }
   193  
   194  __docker_search() {
   195      [[ $PREFIX = -* ]] && return 1
   196      local cache_policy
   197      zstyle -s ":completion:${curcontext}:" cache-policy cache_policy
   198      if [[ -z "$cache_policy" ]]; then
   199          zstyle ":completion:${curcontext}:" cache-policy __docker_caching_policy
   200      fi
   201  
   202      local searchterm cachename
   203      searchterm="${words[$CURRENT]%/}"
   204      cachename=_docker-search-$searchterm
   205  
   206      local expl
   207      local -a result
   208      if ( [[ ${(P)+cachename} -eq 0 ]] || _cache_invalid ${cachename#_} ) \
   209          && ! _retrieve_cache ${cachename#_}; then
   210          _message "Searching for ${searchterm}..."
   211          result=(${${${(f)"$(_call_program commands docker $docker_options search $searchterm)"}%% *}[2,-1]})
   212          _store_cache ${cachename#_} result
   213      fi
   214      _wanted dockersearch expl 'available images' compadd -a result
   215  }
   216  
   217  __docker_get_log_options() {
   218      [[ $PREFIX = -* ]] && return 1
   219  
   220      integer ret=1
   221      local log_driver=${opt_args[--log-driver]:-"all"}
   222      local -a awslogs_options fluentd_options gelf_options journald_options json_file_options syslog_options splunk_options
   223  
   224      awslogs_options=("awslogs-region" "awslogs-group" "awslogs-stream")
   225      fluentd_options=("env" "fluentd-address" "fluentd-async-connect" "fluentd-buffer-limit" "fluentd-retry-wait" "fluentd-max-retries" "labels" "tag")
   226      gcplogs_options=("env" "gcp-log-cmd" "gcp-project" "labels")
   227      gelf_options=("env" "gelf-address" "gelf-compression-level" "gelf-compression-type" "labels" "tag")
   228      journald_options=("env" "labels" "tag")
   229      json_file_options=("env" "labels" "max-file" "max-size")
   230      syslog_options=("env" "labels" "syslog-address" "syslog-facility" "syslog-format" "syslog-tls-ca-cert" "syslog-tls-cert" "syslog-tls-key" "syslog-tls-skip-verify" "tag")
   231      splunk_options=("env" "labels" "splunk-caname" "splunk-capath" "splunk-format" "splunk-gzip" "splunk-gzip-level" "splunk-index" "splunk-insecureskipverify" "splunk-source" "splunk-sourcetype" "splunk-token" "splunk-url" "splunk-verify-connection" "tag")
   232  
   233      [[ $log_driver = (awslogs|all) ]] && _describe -t awslogs-options "awslogs options" awslogs_options "$@" && ret=0
   234      [[ $log_driver = (fluentd|all) ]] && _describe -t fluentd-options "fluentd options" fluentd_options "$@" && ret=0
   235      [[ $log_driver = (gcplogs|all) ]] && _describe -t gcplogs-options "gcplogs options" gcplogs_options "$@" && ret=0
   236      [[ $log_driver = (gelf|all) ]] && _describe -t gelf-options "gelf options" gelf_options "$@" && ret=0
   237      [[ $log_driver = (journald|all) ]] && _describe -t journald-options "journald options" journald_options "$@" && ret=0
   238      [[ $log_driver = (json-file|all) ]] && _describe -t json-file-options "json-file options" json_file_options "$@" && ret=0
   239      [[ $log_driver = (syslog|all) ]] && _describe -t syslog-options "syslog options" syslog_options "$@" && ret=0
   240      [[ $log_driver = (splunk|all) ]] && _describe -t splunk-options "splunk options" splunk_options "$@" && ret=0
   241  
   242      return ret
   243  }
   244  
   245  __docker_log_drivers() {
   246      [[ $PREFIX = -*  ]] && return 1
   247      integer ret=1
   248      drivers=(awslogs etwlogs fluentd gcplogs gelf journald json-file none splunk syslog)
   249      _describe -t log-drivers "log drivers" drivers && ret=0
   250      return ret
   251  }
   252  
   253  __docker_log_options() {
   254      [[ $PREFIX = -* ]] && return 1
   255      integer ret=1
   256  
   257      if compset -P '*='; then
   258          case "${${words[-1]%=*}#*=}" in
   259              (syslog-format)
   260                  syslog_format_opts=('rfc3164' 'rfc5424' 'rfc5424micro')
   261                  _describe -t syslog-format-opts "Syslog format Options" syslog_format_opts && ret=0
   262                  ;;
   263              *)
   264                  _message 'value' && ret=0
   265                  ;;
   266          esac
   267      else
   268          __docker_get_log_options -qS "=" && ret=0
   269      fi
   270  
   271      return ret
   272  }
   273  
   274  __docker_complete_detach_keys() {
   275      [[ $PREFIX = -* ]] && return 1
   276      integer ret=1
   277  
   278      compset -P "*,"
   279      keys=(${:-{a-z}})
   280      ctrl_keys=(${:-ctrl-{{a-z},{@,'[','\\','^',']',_}}})
   281      _describe -t detach_keys "[a-z]" keys -qS "," && ret=0
   282      _describe -t detach_keys-ctrl "'ctrl-' + 'a-z @ [ \\\\ ] ^ _'" ctrl_keys -qS "," && ret=0
   283  }
   284  
   285  __docker_complete_pid() {
   286      [[ $PREFIX = -* ]] && return 1
   287      integer ret=1
   288      local -a opts vopts
   289  
   290      opts=('host')
   291      vopts=('container')
   292  
   293      if compset -P '*:'; then
   294          case "${${words[-1]%:*}#*=}" in
   295              (container)
   296                  __docker_runningcontainers && ret=0
   297                  ;;
   298              *)
   299                  _message 'value' && ret=0
   300                  ;;
   301          esac
   302      else
   303          _describe -t pid-value-opts "PID Options with value" vopts -qS ":" && ret=0
   304          _describe -t pid-opts "PID Options" opts && ret=0
   305      fi
   306  
   307      return ret
   308  }
   309  
   310  __docker_complete_runtimes() {
   311      [[ $PREFIX = -*  ]] && return 1
   312      integer ret=1
   313  
   314      emulate -L zsh
   315      setopt extendedglob
   316      local -a runtimes_opts
   317      runtimes_opts=(${(ps: :)${(f)${${"$(_call_program commands docker $docker_options info)"##*$'\n'Runtimes: }%%$'\n'^ *}}})
   318      _describe -t runtimes-opts "runtimes options" runtimes_opts && ret=0
   319  }
   320  
   321  __docker_complete_ps_filters() {
   322      [[ $PREFIX = -* ]] && return 1
   323      integer ret=1
   324  
   325      if compset -P '*='; then
   326          case "${${words[-1]%=*}#*=}" in
   327              (ancestor)
   328                  __docker_images && ret=0
   329                  ;;
   330              (before|since)
   331                  __docker_containers && ret=0
   332                  ;;
   333              (id)
   334                  __docker_containers_ids && ret=0
   335                  ;;
   336              (is-task)
   337                  _describe -t boolean-filter-opts "filter options" boolean_opts && ret=0
   338                  ;;
   339              (name)
   340                  __docker_containers_names && ret=0
   341                  ;;
   342              (network)
   343                  __docker_networks && ret=0
   344                  ;;
   345              (status)
   346                  status_opts=('created' 'dead' 'exited' 'paused' 'restarting' 'running' 'removing')
   347                  _describe -t status-filter-opts "Status Filter Options" status_opts && ret=0
   348                  ;;
   349              (volume)
   350                  __docker_volumes && ret=0
   351                  ;;
   352              *)
   353                  _message 'value' && ret=0
   354                  ;;
   355          esac
   356      else
   357          opts=('ancestor' 'before' 'exited' 'id' 'label' 'name' 'network' 'since' 'status' 'volume')
   358          _describe -t filter-opts "Filter Options" opts -qS "=" && ret=0
   359      fi
   360  
   361      return ret
   362  }
   363  
   364  __docker_complete_search_filters() {
   365      [[ $PREFIX = -* ]] && return 1
   366      integer ret=1
   367      declare -a boolean_opts opts
   368  
   369      boolean_opts=('true' 'false')
   370      opts=('is-automated' 'is-official' 'stars')
   371  
   372      if compset -P '*='; then
   373          case "${${words[-1]%=*}#*=}" in
   374              (is-automated|is-official)
   375                  _describe -t boolean-filter-opts "filter options" boolean_opts && ret=0
   376                  ;;
   377              *)
   378                  _message 'value' && ret=0
   379                  ;;
   380          esac
   381      else
   382          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
   383      fi
   384  
   385      return ret
   386  }
   387  
   388  __docker_complete_images_filters() {
   389      [[ $PREFIX = -* ]] && return 1
   390      integer ret=1
   391      declare -a boolean_opts opts
   392  
   393      boolean_opts=('true' 'false')
   394      opts=('before' 'dangling' 'label' 'since')
   395  
   396      if compset -P '*='; then
   397          case "${${words[-1]%=*}#*=}" in
   398              (before|since)
   399                  __docker_images && ret=0
   400                  ;;
   401              (dangling)
   402                  _describe -t boolean-filter-opts "filter options" boolean_opts && ret=0
   403                  ;;
   404              *)
   405                  _message 'value' && ret=0
   406                  ;;
   407          esac
   408      else
   409          _describe -t filter-opts "Filter Options" opts -qS "=" && ret=0
   410      fi
   411  
   412      return ret
   413  }
   414  
   415  __docker_complete_events_filter() {
   416      [[ $PREFIX = -* ]] && return 1
   417      integer ret=1
   418      declare -a opts
   419  
   420      opts=('container' 'daemon' 'event' 'image' 'label' 'network' 'type' 'volume')
   421  
   422      if compset -P '*='; then
   423          case "${${words[-1]%=*}#*=}" in
   424              (container)
   425                  __docker_containers && ret=0
   426                  ;;
   427              (daemon)
   428                  emulate -L zsh
   429                  setopt extendedglob
   430                  local -a daemon_opts
   431                  daemon_opts=(
   432                      ${(f)${${"$(_call_program commands docker $docker_options info)"##*$'\n'Name: }%%$'\n'^ *}}
   433                      ${${(f)${${"$(_call_program commands docker $docker_options info)"##*$'\n'ID: }%%$'\n'^ *}}//:/\\:}
   434                  )
   435                  _describe -t daemon-filter-opts "daemon filter options" daemon_opts && ret=0
   436                  ;;
   437              (event)
   438                  local -a event_opts
   439                  event_opts=('attach' 'commit' 'connect' 'copy' 'create' 'delete' 'destroy' 'detach' 'die' 'disconnect' 'exec_create' 'exec_detach'
   440                  'exec_start' 'export' 'health_status' 'import' 'kill' 'load'  'mount' 'oom' 'pause' 'pull' 'push' 'reload' 'rename' 'resize' 'restart' 'save' 'start'
   441                  'stop' 'tag' 'top' 'unmount' 'unpause' 'untag' 'update')
   442                  _describe -t event-filter-opts "event filter options" event_opts && ret=0
   443                  ;;
   444              (image)
   445                  __docker_images && ret=0
   446                  ;;
   447              (network)
   448                  __docker_networks && ret=0
   449                  ;;
   450              (type)
   451                  local -a type_opts
   452                  type_opts=('container' 'daemon' 'image' 'network' 'volume')
   453                  _describe -t type-filter-opts "type filter options" type_opts && ret=0
   454                  ;;
   455              (volume)
   456                  __docker_volumes && ret=0
   457                  ;;
   458              *)
   459                  _message 'value' && ret=0
   460                  ;;
   461          esac
   462      else
   463          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
   464      fi
   465  
   466      return ret
   467  }
   468  
   469  # BO network
   470  
   471  __docker_network_complete_ls_filters() {
   472      [[ $PREFIX = -* ]] && return 1
   473      integer ret=1
   474  
   475      if compset -P '*='; then
   476          case "${${words[-1]%=*}#*=}" in
   477              (driver)
   478                  __docker_complete_info_plugins Network && ret=0
   479                  ;;
   480              (id)
   481                  __docker_networks_ids && ret=0
   482                  ;;
   483              (name)
   484                  __docker_networks_names && ret=0
   485                  ;;
   486              (type)
   487                  type_opts=('builtin' 'custom')
   488                  _describe -t type-filter-opts "Type Filter Options" type_opts && ret=0
   489                  ;;
   490              *)
   491                  _message 'value' && ret=0
   492                  ;;
   493          esac
   494      else
   495          opts=('driver' 'id' 'label' 'name' 'type')
   496          _describe -t filter-opts "Filter Options" opts -qS "=" && ret=0
   497      fi
   498  
   499      return ret
   500  }
   501  
   502  __docker_get_networks() {
   503      [[ $PREFIX = -* ]] && return 1
   504      integer ret=1
   505      local line s
   506      declare -a lines networks
   507  
   508      type=$1; shift
   509  
   510      lines=(${(f)"$(_call_program commands docker $docker_options network ls)"})
   511  
   512      # Parse header line to find columns
   513      local i=1 j=1 k header=${lines[1]}
   514      declare -A begin end
   515      while (( j < ${#header} - 1 )); do
   516          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
   517          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
   518          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
   519          begin[${header[$i,$((j-1))]}]=$i
   520          end[${header[$i,$((j-1))]}]=$k
   521      done
   522      end[${header[$i,$((j-1))]}]=-1
   523      lines=(${lines[2,-1]})
   524  
   525      # Network ID
   526      if [[ $type = (ids|all) ]]; then
   527          for line in $lines; do
   528              s="${line[${begin[NETWORK ID]},${end[NETWORK ID]}]%% ##}"
   529              s="$s:${(l:7:: :::)${${line[${begin[DRIVER]},${end[DRIVER]}]}%% ##}}"
   530              networks=($networks $s)
   531          done
   532      fi
   533  
   534      # Names
   535      if [[ $type = (names|all) ]]; then
   536          for line in $lines; do
   537              s="${line[${begin[NAME]},${end[NAME]}]%% ##}"
   538              s="$s:${(l:7:: :::)${${line[${begin[DRIVER]},${end[DRIVER]}]}%% ##}}"
   539              networks=($networks $s)
   540          done
   541      fi
   542  
   543      _describe -t networks-list "networks" networks "$@" && ret=0
   544      return ret
   545  }
   546  
   547  __docker_networks() {
   548      [[ $PREFIX = -* ]] && return 1
   549      __docker_get_networks all "$@"
   550  }
   551  
   552  __docker_networks_ids() {
   553      [[ $PREFIX = -* ]] && return 1
   554      __docker_get_networks ids "$@"
   555  }
   556  
   557  __docker_networks_names() {
   558      [[ $PREFIX = -* ]] && return 1
   559      __docker_get_networks names "$@"
   560  }
   561  
   562  __docker_network_commands() {
   563      local -a _docker_network_subcommands
   564      _docker_network_subcommands=(
   565          "connect:Connect a container to a network"
   566          "create:Creates a new network with a name specified by the user"
   567          "disconnect:Disconnects a container from a network"
   568          "inspect:Displays detailed information on a network"
   569          "ls:Lists all the networks created by the user"
   570          "rm:Deletes one or more networks"
   571      )
   572      _describe -t docker-network-commands "docker network command" _docker_network_subcommands
   573  }
   574  
   575  __docker_network_subcommand() {
   576      local -a _command_args opts_help
   577      local expl help="--help"
   578      integer ret=1
   579  
   580      opts_help=("(: -)--help[Print usage]")
   581  
   582      case "$words[1]" in
   583          (connect)
   584              _arguments $(__docker_arguments) \
   585                  $opts_help \
   586                  "($help)*--alias=[Add network-scoped alias for the container]:alias: " \
   587                  "($help)--ip=[Container IPv4 address]:IPv4: " \
   588                  "($help)--ip6=[Container IPv6 address]:IPv6: " \
   589                  "($help)*--link=[Add a link to another container]:link:->link" \
   590                  "($help)*--link-local-ip=[Add a link-local address for the container]:IPv4/IPv6: " \
   591                  "($help -)1:network:__docker_networks" \
   592                  "($help -)2:containers:__docker_containers" && ret=0
   593  
   594              case $state in
   595                  (link)
   596                      if compset -P "*:"; then
   597                          _wanted alias expl "Alias" compadd -E "" && ret=0
   598                      else
   599                          __docker_runningcontainers -qS ":" && ret=0
   600                      fi
   601                      ;;
   602              esac
   603              ;;
   604          (create)
   605              _arguments $(__docker_arguments) -A '-*' \
   606                  $opts_help \
   607                  "($help)*--aux-address[Auxiliary IPv4 or IPv6 addresses used by network driver]:key=IP: " \
   608                  "($help -d --driver)"{-d=,--driver=}"[Driver to manage the Network]:driver:(null host bridge overlay)" \
   609                  "($help)*--gateway=[IPv4 or IPv6 Gateway for the master subnet]:IP: " \
   610                  "($help)--internal[Restricts external access to the network]" \
   611                  "($help)*--ip-range=[Allocate container ip from a sub-range]:IP/mask: " \
   612                  "($help)--ipam-driver=[IP Address Management Driver]:driver:(default)" \
   613                  "($help)*--ipam-opt=[Custom IPAM plugin options]:opt=value: " \
   614                  "($help)--ipv6[Enable IPv6 networking]" \
   615                  "($help)*--label=[Set metadata on a network]:label=value: " \
   616                  "($help)*"{-o=,--opt=}"[Driver specific options]:opt=value: " \
   617                  "($help)*--subnet=[Subnet in CIDR format that represents a network segment]:IP/mask: " \
   618                  "($help -)1:Network Name: " && ret=0
   619              ;;
   620          (disconnect)
   621              _arguments $(__docker_arguments) \
   622                  $opts_help \
   623                  "($help -)1:network:__docker_networks" \
   624                  "($help -)2:containers:__docker_containers" && ret=0
   625              ;;
   626          (inspect)
   627              _arguments $(__docker_arguments) \
   628                  $opts_help \
   629                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " \
   630                  "($help -)*:network:__docker_networks" && ret=0
   631              ;;
   632          (ls)
   633              _arguments $(__docker_arguments) \
   634                  $opts_help \
   635                  "($help)--no-trunc[Do not truncate the output]" \
   636                  "($help)*"{-f=,--filter=}"[Provide filter values]:filter:->filter-options" \
   637                  "($help)--format=[Pretty-print networks using a Go template]:template: " \
   638                  "($help -q --quiet)"{-q,--quiet}"[Only display numeric IDs]" && ret=0
   639              case $state in
   640                  (filter-options)
   641                      __docker_network_complete_ls_filters && ret=0
   642                      ;;
   643              esac
   644              ;;
   645          (rm)
   646              _arguments $(__docker_arguments) \
   647                  $opts_help \
   648                  "($help -)*:network:__docker_networks" && ret=0
   649              ;;
   650          (help)
   651              _arguments $(__docker_arguments) ":subcommand:__docker_network_commands" && ret=0
   652              ;;
   653      esac
   654  
   655      return ret
   656  }
   657  
   658  # EO network
   659  
   660  # BO node
   661  
   662  __docker_node_complete_ls_filters() {
   663      [[ $PREFIX = -* ]] && return 1
   664      integer ret=1
   665  
   666      if compset -P '*='; then
   667          case "${${words[-1]%=*}#*=}" in
   668              (id)
   669                  __docker_complete_nodes_ids && ret=0
   670                  ;;
   671              (membership)
   672                  membership_opts=('accepted' 'pending' 'rejected')
   673                  _describe -t membership-opts "membership options" membership_opts && ret=0
   674                  ;;
   675              (name)
   676                  __docker_complete_nodes_names && ret=0
   677                  ;;
   678              (role)
   679                  role_opts=('manager' 'worker')
   680                  _describe -t role-opts "role options" role_opts && ret=0
   681                  ;;
   682              *)
   683                  _message 'value' && ret=0
   684                  ;;
   685          esac
   686      else
   687          opts=('id' 'label' 'membership' 'name' 'role')
   688          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
   689      fi
   690  
   691      return ret
   692  }
   693  
   694  __docker_node_complete_ps_filters() {
   695      [[ $PREFIX = -* ]] && return 1
   696      integer ret=1
   697  
   698      if compset -P '*='; then
   699          case "${${words[-1]%=*}#*=}" in
   700              (desired-state)
   701                  state_opts=('accepted' 'running')
   702                  _describe -t state-opts "desired state options" state_opts && ret=0
   703                  ;;
   704              *)
   705                  _message 'value' && ret=0
   706                  ;;
   707          esac
   708      else
   709          opts=('desired-state' 'id' 'label' 'name')
   710          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
   711      fi
   712  
   713      return ret
   714  }
   715  
   716  __docker_nodes() {
   717      [[ $PREFIX = -* ]] && return 1
   718      integer ret=1
   719      local line s
   720      declare -a lines nodes args
   721  
   722      type=$1; shift
   723      filter=$1; shift
   724      [[ $filter != "none" ]] && args=("-f $filter")
   725  
   726      lines=(${(f)"$(_call_program commands docker $docker_options node ls $args)"})
   727      # Parse header line to find columns
   728      local i=1 j=1 k header=${lines[1]}
   729      declare -A begin end
   730      while (( j < ${#header} - 1 )); do
   731          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
   732          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
   733          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
   734          begin[${header[$i,$((j-1))]}]=$i
   735          end[${header[$i,$((j-1))]}]=$k
   736      done
   737      end[${header[$i,$((j-1))]}]=-1
   738      lines=(${lines[2,-1]})
   739  
   740      # Node ID
   741      if [[ $type = (ids|all) ]]; then
   742          for line in $lines; do
   743              s="${line[${begin[ID]},${end[ID]}]%% ##}"
   744              nodes=($nodes $s)
   745          done
   746      fi
   747  
   748      # Names
   749      if [[ $type = (names|all) ]]; then
   750          for line in $lines; do
   751              s="${line[${begin[NAME]},${end[NAME]}]%% ##}"
   752              nodes=($nodes $s)
   753          done
   754      fi
   755  
   756      _describe -t nodes-list "nodes" nodes "$@" && ret=0
   757      return ret
   758  }
   759  
   760  __docker_complete_nodes() {
   761      [[ $PREFIX = -* ]] && return 1
   762      __docker_nodes all none "$@"
   763  }
   764  
   765  __docker_complete_nodes_ids() {
   766      [[ $PREFIX = -* ]] && return 1
   767      __docker_nodes ids none "$@"
   768  }
   769  
   770  __docker_complete_nodes_names() {
   771      [[ $PREFIX = -* ]] && return 1
   772      __docker_nodes names none "$@"
   773  }
   774  
   775  __docker_complete_pending_nodes() {
   776      [[ $PREFIX = -* ]] && return 1
   777      __docker_nodes all "membership=pending" "$@"
   778  }
   779  
   780  __docker_complete_manager_nodes() {
   781      [[ $PREFIX = -* ]] && return 1
   782      __docker_nodes all "role=manager" "$@"
   783  }
   784  
   785  __docker_complete_worker_nodes() {
   786      [[ $PREFIX = -* ]] && return 1
   787      __docker_nodes all "role=worker" "$@"
   788  }
   789  
   790  __docker_node_commands() {
   791      local -a _docker_node_subcommands
   792      _docker_node_subcommands=(
   793          "demote:Demote a node as manager in the swarm"
   794          "inspect:Display detailed information on one or more nodes"
   795          "ls:List nodes in the swarm"
   796          "promote:Promote a node as manager in the swarm"
   797          "rm:Remove one or more nodes from the swarm"
   798          "ps:List tasks running on one or more nodes, defaults to current node"
   799          "update:Update a node"
   800      )
   801      _describe -t docker-node-commands "docker node command" _docker_node_subcommands
   802  }
   803  
   804  __docker_node_subcommand() {
   805      local -a _command_args opts_help
   806      local expl help="--help"
   807      integer ret=1
   808  
   809      opts_help=("(: -)--help[Print usage]")
   810  
   811      case "$words[1]" in
   812          (rm|remove)
   813               _arguments $(__docker_arguments) \
   814                  $opts_help \
   815                  "($help)--force[Force remove an active node]" \
   816                  "($help -)*:node:__docker_complete_pending_nodes" && ret=0
   817              ;;
   818          (demote)
   819               _arguments $(__docker_arguments) \
   820                  $opts_help \
   821                  "($help -)*:node:__docker_complete_manager_nodes" && ret=0
   822              ;;
   823          (inspect)
   824              _arguments $(__docker_arguments) \
   825                  $opts_help \
   826                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " \
   827                  "($help)--pretty[Print the information in a human friendly format]" \
   828                  "($help -)*:node:__docker_complete_nodes" && ret=0
   829              ;;
   830          (ls|list)
   831              _arguments $(__docker_arguments) \
   832                  $opts_help \
   833                  "($help)*"{-f=,--filter=}"[Provide filter values]:filter:->filter-options" \
   834                  "($help -q --quiet)"{-q,--quiet}"[Only display IDs]" && ret=0
   835              case $state in
   836                  (filter-options)
   837                      __docker_node_complete_ls_filters && ret=0
   838                      ;;
   839              esac
   840              ;;
   841          (promote)
   842               _arguments $(__docker_arguments) \
   843                  $opts_help \
   844                  "($help -)*:node:__docker_complete_worker_nodes" && ret=0
   845              ;;
   846          (ps)
   847              _arguments $(__docker_arguments) \
   848                  $opts_help \
   849                  "($help -a --all)"{-a,--all}"[Display all instances]" \
   850                  "($help)*"{-f=,--filter=}"[Provide filter values]:filter:->filter-options" \
   851                  "($help)--no-resolve[Do not map IDs to Names]" \
   852                  "($help)--no-trunc[Do not truncate output]" \
   853                  "($help -)*:node:__docker_complete_nodes" && ret=0
   854              case $state in
   855                  (filter-options)
   856                      __docker_node_complete_ps_filters && ret=0
   857                      ;;
   858              esac
   859              ;;
   860          (update)
   861              _arguments $(__docker_arguments) \
   862                  $opts_help \
   863                  "($help)--availability=[Availability of the node]:availability:(active pause drain)" \
   864                  "($help)*--label-add=[Add or update a node label]:key=value: " \
   865                  "($help)*--label-rm=[Remove a node label if exists]:label: " \
   866                  "($help)--role=[Role of the node]:role:(manager worker)" \
   867                  "($help -)1:node:__docker_complete_nodes" && ret=0
   868              ;;
   869          (help)
   870              _arguments $(__docker_arguments) ":subcommand:__docker_node_commands" && ret=0
   871              ;;
   872      esac
   873  
   874      return ret
   875  }
   876  
   877  # EO node
   878  
   879  # BO plugin
   880  
   881  __docker_complete_plugins() {
   882      [[ $PREFIX = -* ]] && return 1
   883      integer ret=1
   884      local line s
   885      declare -a lines plugins
   886  
   887      lines=(${(f)"$(_call_program commands docker $docker_options plugin ls)"})
   888  
   889      # Parse header line to find columns
   890      local i=1 j=1 k header=${lines[1]}
   891      declare -A begin end
   892      while (( j < ${#header} - 1 )); do
   893          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
   894          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
   895          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
   896          begin[${header[$i,$((j-1))]}]=$i
   897          end[${header[$i,$((j-1))]}]=$k
   898      done
   899      end[${header[$i,$((j-1))]}]=-1
   900      lines=(${lines[2,-1]})
   901  
   902      # Name
   903      for line in $lines; do
   904          s="${line[${begin[NAME]},${end[NAME]}]%% ##}"
   905          s="$s:${(l:7:: :::)${${line[${begin[TAG]},${end[TAG]}]}%% ##}}"
   906          plugins=($plugins $s)
   907      done
   908  
   909      _describe -t plugins-list "plugins" plugins "$@" && ret=0
   910      return ret
   911  }
   912  
   913  __docker_plugin_commands() {
   914      local -a _docker_plugin_subcommands
   915      _docker_plugin_subcommands=(
   916          "disable:Disable a plugin"
   917          "enable:Enable a plugin"
   918          "inspect:Return low-level information about a plugin"
   919          "install:Install a plugin"
   920          "ls:List plugins"
   921          "push:Push a plugin"
   922          "rm:Remove a plugin"
   923          "set:Change settings for a plugin"
   924      )
   925      _describe -t docker-plugin-commands "docker plugin command" _docker_plugin_subcommands
   926  }
   927  
   928  __docker_plugin_subcommand() {
   929      local -a _command_args opts_help
   930      local expl help="--help"
   931      integer ret=1
   932  
   933      opts_help=("(: -)--help[Print usage]")
   934  
   935      case "$words[1]" in
   936          (disable|enable|inspect|install|ls|push|rm)
   937              _arguments $(__docker_arguments) \
   938                  $opts_help \
   939                  "($help -)1:plugin:__docker_complete_plugins" && ret=0
   940              ;;
   941          (set)
   942              _arguments $(__docker_arguments) \
   943                  $opts_help \
   944                  "($help -)1:plugin:__docker_complete_plugins" \
   945                  "($help-)*:key=value: " && ret=0
   946              ;;
   947          (help)
   948              _arguments $(__docker_arguments) ":subcommand:__docker_plugin_commands" && ret=0
   949              ;;
   950      esac
   951  
   952      return ret
   953  }
   954  
   955  # EO plugin
   956  
   957  # BO service
   958  
   959  __docker_service_complete_ls_filters() {
   960      [[ $PREFIX = -* ]] && return 1
   961      integer ret=1
   962  
   963      if compset -P '*='; then
   964          case "${${words[-1]%=*}#*=}" in
   965              (id)
   966                  __docker_complete_services_ids && ret=0
   967                  ;;
   968              (name)
   969                  __docker_complete_services_names && ret=0
   970                  ;;
   971              *)
   972                  _message 'value' && ret=0
   973                  ;;
   974          esac
   975      else
   976          opts=('id' 'label' 'name')
   977          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
   978      fi
   979  
   980      return ret
   981  }
   982  
   983  __docker_service_complete_ps_filters() {
   984      [[ $PREFIX = -* ]] && return 1
   985      integer ret=1
   986  
   987      if compset -P '*='; then
   988          case "${${words[-1]%=*}#*=}" in
   989              (desired-state)
   990                  state_opts=('accepted' 'running')
   991                  _describe -t state-opts "desired state options" state_opts && ret=0
   992                  ;;
   993              *)
   994                  _message 'value' && ret=0
   995                  ;;
   996          esac
   997      else
   998          opts=('desired-state' 'id' 'label' 'name')
   999          _describe -t filter-opts "filter options" opts -qS "=" && ret=0
  1000      fi
  1001  
  1002      return ret
  1003  }
  1004  
  1005  __docker_services() {
  1006      [[ $PREFIX = -* ]] && return 1
  1007      integer ret=1
  1008      local line s
  1009      declare -a lines services
  1010  
  1011      type=$1; shift
  1012  
  1013      lines=(${(f)"$(_call_program commands docker $docker_options service ls)"})
  1014  
  1015      # Parse header line to find columns
  1016      local i=1 j=1 k header=${lines[1]}
  1017      declare -A begin end
  1018      while (( j < ${#header} - 1 )); do
  1019          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
  1020          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
  1021          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
  1022          begin[${header[$i,$((j-1))]}]=$i
  1023          end[${header[$i,$((j-1))]}]=$k
  1024      done
  1025      end[${header[$i,$((j-1))]}]=-1
  1026      lines=(${lines[2,-1]})
  1027  
  1028      # Service ID
  1029      if [[ $type = (ids|all) ]]; then
  1030          for line in $lines; do
  1031              s="${line[${begin[ID]},${end[ID]}]%% ##}"
  1032              s="$s:${(l:7:: :::)${${line[${begin[IMAGE]},${end[IMAGE]}]}%% ##}}"
  1033              services=($services $s)
  1034          done
  1035      fi
  1036  
  1037      # Names
  1038      if [[ $type = (names|all) ]]; then
  1039          for line in $lines; do
  1040              s="${line[${begin[NAME]},${end[NAME]}]%% ##}"
  1041              s="$s:${(l:7:: :::)${${line[${begin[IMAGE]},${end[IMAGE]}]}%% ##}}"
  1042              services=($services $s)
  1043          done
  1044      fi
  1045  
  1046      _describe -t services-list "services" services "$@" && ret=0
  1047      return ret
  1048  }
  1049  
  1050  __docker_complete_services() {
  1051      [[ $PREFIX = -* ]] && return 1
  1052      __docker_services all "$@"
  1053  }
  1054  
  1055  __docker_complete_services_ids() {
  1056      [[ $PREFIX = -* ]] && return 1
  1057      __docker_services ids "$@"
  1058  }
  1059  
  1060  __docker_complete_services_names() {
  1061      [[ $PREFIX = -* ]] && return 1
  1062      __docker_services names "$@"
  1063  }
  1064  
  1065  __docker_service_commands() {
  1066      local -a _docker_service_subcommands
  1067      _docker_service_subcommands=(
  1068          "create:Create a new service"
  1069          "inspect:Display detailed information on one or more services"
  1070          "ls:List services"
  1071          "rm:Remove one or more services"
  1072          "scale:Scale one or multiple services"
  1073          "ps:List the tasks of a service"
  1074          "update:Update a service"
  1075      )
  1076      _describe -t docker-service-commands "docker service command" _docker_service_subcommands
  1077  }
  1078  
  1079  __docker_service_subcommand() {
  1080      local -a _command_args opts_help opts_create_update
  1081      local expl help="--help"
  1082      integer ret=1
  1083  
  1084      opts_help=("(: -)--help[Print usage]")
  1085      opts_create_update=(
  1086          "($help)*--constraint=[Placement constraints]:constraint: "
  1087          "($help)--endpoint-mode=[Placement constraints]:mode:(dnsrr vip)"
  1088          "($help)*"{-e=,--env=}"[Set environment variables]:env: "
  1089          "($help)*--group-add=[Add additional user groups to the container]:group:_groups"
  1090          "($help)*--label=[Service labels]:label: "
  1091          "($help)--limit-cpu=[Limit CPUs]:value: "
  1092          "($help)--limit-memory=[Limit Memory]:value: "
  1093          "($help)--log-driver=[Logging driver for service]:logging driver:__docker_log_drivers"
  1094          "($help)*--log-opt=[Logging driver options]:log driver options:__docker_log_options"
  1095          "($help)*--mount=[Attach a mount to the service]:mount: "
  1096          "($help)--name=[Service name]:name: "
  1097          "($help)*--network=[Network attachments]:network: "
  1098          "($help)*"{-p=,--publish=}"[Publish a port as a node port]:port: "
  1099          "($help)--replicas=[Number of tasks]:replicas: "
  1100          "($help)--reserve-cpu=[Reserve CPUs]:value: "
  1101          "($help)--reserve-memory=[Reserve Memory]:value: "
  1102          "($help)--restart-condition=[Restart when condition is met]:mode:(any none on-failure)"
  1103          "($help)--restart-delay=[Delay between restart attempts]:delay: "
  1104          "($help)--restart-max-attempts=[Maximum number of restarts before giving up]:max-attempts: "
  1105          "($help)--restart-window=[Window used to evaluate the restart policy]:window: "
  1106          "($help)--stop-grace-period=[Time to wait before force killing a container]:grace period: "
  1107          "($help)--update-delay=[Delay between updates]:delay: "
  1108          "($help)--update-failure-action=[Action on update failure]:mode:(pause continue)"
  1109          "($help)--update-parallelism=[Maximum number of tasks updated simultaneously]:number: "
  1110          "($help -u --user)"{-u=,--user=}"[Username or UID]:user:_users"
  1111          "($help)--with-registry-auth[Send registry authentication details to swarm agents]"
  1112          "($help -w --workdir)"{-w=,--workdir=}"[Working directory inside the container]:directory:_directories"
  1113      )
  1114  
  1115      case "$words[1]" in
  1116          (create)
  1117              _arguments $(__docker_arguments) \
  1118                  $opts_help \
  1119                  $opts_create_update \
  1120                  "($help)*--container-label=[Container labels]:label: " \
  1121                  "($help)--mode=[Service Mode]:mode:(global replicated)" \
  1122                  "($help -): :__docker_images" \
  1123                  "($help -):command: _command_names -e" \
  1124                  "($help -)*::arguments: _normal" && ret=0
  1125              ;;
  1126          (inspect)
  1127              _arguments $(__docker_arguments) \
  1128                  $opts_help \
  1129                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " \
  1130                  "($help)--pretty[Print the information in a human friendly format]" \
  1131                  "($help -)*:service:__docker_complete_services" && ret=0
  1132              ;;
  1133          (ls|list)
  1134              _arguments $(__docker_arguments) \
  1135                  $opts_help \
  1136                  "($help)*"{-f=,--filter=}"[Filter output based on conditions provided]:filter:->filter-options" \
  1137                  "($help -q --quiet)"{-q,--quiet}"[Only display IDs]" && ret=0
  1138              case $state in
  1139                  (filter-options)
  1140                      __docker_service_complete_ls_filters && ret=0
  1141                      ;;
  1142              esac
  1143              ;;
  1144          (rm|remove)
  1145              _arguments $(__docker_arguments) \
  1146                  $opts_help \
  1147                  "($help -)*:service:__docker_complete_services" && ret=0
  1148              ;;
  1149          (scale)
  1150              _arguments $(__docker_arguments) \
  1151                  $opts_help \
  1152                  "($help -)*:service:->values" && ret=0
  1153              case $state in
  1154                  (values)
  1155                      if compset -P '*='; then
  1156                          _message 'replicas' && ret=0
  1157                      else
  1158                          __docker_complete_services -qS "="
  1159                      fi
  1160                      ;;
  1161              esac
  1162              ;;
  1163          (ps)
  1164              _arguments $(__docker_arguments) \
  1165                  $opts_help \
  1166                  "($help -a --all)"{-a,--all}"[Display all tasks]" \
  1167                  "($help)*"{-f=,--filter=}"[Provide filter values]:filter:->filter-options" \
  1168                  "($help)--no-resolve[Do not map IDs to Names]" \
  1169                  "($help)--no-trunc[Do not truncate output]" \
  1170                  "($help -)1:service:__docker_complete_services" && ret=0
  1171              case $state in
  1172                  (filter-options)
  1173                      __docker_service_complete_ps_filters && ret=0
  1174                      ;;
  1175              esac
  1176              ;;
  1177          (update)
  1178              _arguments $(__docker_arguments) \
  1179                  $opts_help \
  1180                  $opts_create_update \
  1181                  "($help)--arg=[Service command args]:arguments: _normal" \
  1182                  "($help)*--container-label-add=[Add or update container labels]:label: " \
  1183                  "($help)*--container-label-rm=[Remove a container label by its key]:label: " \
  1184                  "($help)*--group-rm=[Remove previously added user groups from the container]:group:_groups" \
  1185                  "($help)--image=[Service image tag]:image:__docker_repositories" \
  1186                  "($help -)1:service:__docker_complete_services" && ret=0
  1187              ;;
  1188          (help)
  1189              _arguments $(__docker_arguments) ":subcommand:__docker_service_commands" && ret=0
  1190              ;;
  1191      esac
  1192  
  1193      return ret
  1194  }
  1195  
  1196  # EO service
  1197  
  1198  # BO swarm
  1199  
  1200  __docker_swarm_commands() {
  1201      local -a _docker_swarm_subcommands
  1202      _docker_swarm_subcommands=(
  1203          "init:Initialize a swarm"
  1204          "join:Join a swarm as a node and/or manager"
  1205          "join-token:Manage join tokens"
  1206          "leave:Leave a swarm"
  1207          "update:Update the swarm"
  1208      )
  1209      _describe -t docker-swarm-commands "docker swarm command" _docker_swarm_subcommands
  1210  }
  1211  
  1212  __docker_swarm_subcommand() {
  1213      local -a _command_args opts_help
  1214      local expl help="--help"
  1215      integer ret=1
  1216  
  1217      opts_help=("(: -)--help[Print usage]")
  1218  
  1219      case "$words[1]" in
  1220          (init)
  1221              _arguments $(__docker_arguments) \
  1222                  $opts_help \
  1223                  "($help)--advertise-addr[Advertised address]:ip\:port: " \
  1224                  "($help)*--external-ca=[Specifications of one or more certificate signing endpoints]:endpoint: " \
  1225                  "($help)--force-new-cluster[Force create a new cluster from current state]" \
  1226                  "($help)--listen-addr=[Listen address]:ip\:port: " && ret=0
  1227              ;;
  1228          (join)
  1229              _arguments $(__docker_arguments) \
  1230                  $opts_help \
  1231                  "($help)--advertise-addr[Advertised address]:ip\:port: " \
  1232                  "($help)--listen-addr=[Listen address]:ip\:port: " \
  1233                  "($help)--token=[Token for entry into the swarm]:secret: " \
  1234                  "($help -):host\:port: " && ret=0
  1235              ;;
  1236          (join-token)
  1237              _arguments $(__docker_arguments) \
  1238                  $opts_help \
  1239                  "($help -q --quiet)"{-q,--quiet}"[Only display token]" \
  1240                  "($help)--rotate[Rotate join token]" \
  1241                  "($help -):role:(manager worker)" && ret=0
  1242              ;;
  1243          (leave)
  1244              _arguments $(__docker_arguments) \
  1245                  $opts_help && ret=0
  1246              ;;
  1247          (update)
  1248              _arguments $(__docker_arguments) \
  1249                  $opts_help \
  1250                  "($help)--cert-expiry=[Validity period for node certificates]:duration: " \
  1251                  "($help)--dispatcher-heartbeat=[Dispatcher heartbeat period]:duration: " \
  1252                  "($help)--task-history-limit=[Task history retention limit]:limit: " && ret=0
  1253              ;;
  1254          (help)
  1255              _arguments $(__docker_arguments) ":subcommand:__docker_network_commands" && ret=0
  1256              ;;
  1257      esac
  1258  
  1259      return ret
  1260  }
  1261  
  1262  # EO swarm
  1263  
  1264  # BO volume
  1265  
  1266  __docker_volume_complete_ls_filters() {
  1267      [[ $PREFIX = -* ]] && return 1
  1268      integer ret=1
  1269  
  1270      if compset -P '*='; then
  1271          case "${${words[-1]%=*}#*=}" in
  1272              (dangling)
  1273                  dangling_opts=('true' 'false')
  1274                  _describe -t dangling-filter-opts "Dangling Filter Options" dangling_opts && ret=0
  1275                  ;;
  1276              (driver)
  1277                  __docker_complete_info_plugins Volume && ret=0
  1278                  ;;
  1279              (name)
  1280                  __docker_volumes && ret=0
  1281                  ;;
  1282              *)
  1283                  _message 'value' && ret=0
  1284                  ;;
  1285          esac
  1286      else
  1287          opts=('dangling' 'driver' 'label' 'name')
  1288          _describe -t filter-opts "Filter Options" opts -qS "=" && ret=0
  1289      fi
  1290  
  1291      return ret
  1292  }
  1293  
  1294  __docker_volumes() {
  1295      [[ $PREFIX = -* ]] && return 1
  1296      integer ret=1
  1297      declare -a lines volumes
  1298  
  1299      lines=(${(f)"$(_call_program commands docker $docker_options volume ls)"})
  1300  
  1301      # Parse header line to find columns
  1302      local i=1 j=1 k header=${lines[1]}
  1303      declare -A begin end
  1304      while (( j < ${#header} - 1 )); do
  1305          i=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 1 ))
  1306          j=$(( i + ${${header[$i,-1]}[(i)  ]} - 1 ))
  1307          k=$(( j + ${${header[$j,-1]}[(i)[^ ]]} - 2 ))
  1308          begin[${header[$i,$((j-1))]}]=$i
  1309          end[${header[$i,$((j-1))]}]=$k
  1310      done
  1311      end[${header[$i,$((j-1))]}]=-1
  1312      lines=(${lines[2,-1]})
  1313  
  1314      # Names
  1315      local line s
  1316      for line in $lines; do
  1317          s="${line[${begin[VOLUME NAME]},${end[VOLUME NAME]}]%% ##}"
  1318          s="$s:${(l:7:: :::)${${line[${begin[DRIVER]},${end[DRIVER]}]}%% ##}}"
  1319          volumes=($volumes $s)
  1320      done
  1321  
  1322      _describe -t volumes-list "volumes" volumes && ret=0
  1323      return ret
  1324  }
  1325  
  1326  __docker_volume_commands() {
  1327      local -a _docker_volume_subcommands
  1328      _docker_volume_subcommands=(
  1329          "create:Create a volume"
  1330          "inspect:Display detailed information on one or more volumes"
  1331          "ls:List volumes"
  1332          "rm:Remove one or more volumes"
  1333      )
  1334      _describe -t docker-volume-commands "docker volume command" _docker_volume_subcommands
  1335  }
  1336  
  1337  __docker_volume_subcommand() {
  1338      local -a _command_args opts_help
  1339      local expl help="--help"
  1340      integer ret=1
  1341  
  1342      opts_help=("(: -)--help[Print usage]")
  1343  
  1344      case "$words[1]" in
  1345          (create)
  1346              _arguments $(__docker_arguments) -A '-*' \
  1347                  $opts_help \
  1348                  "($help -d --driver)"{-d=,--driver=}"[Volume driver name]:Driver name:(local)" \
  1349                  "($help)*--label=[Set metadata for a volume]:label=value: " \
  1350                  "($help)*"{-o=,--opt=}"[Driver specific options]:Driver option: " \
  1351                  "($help -)1:Volume name: " && ret=0
  1352              ;;
  1353          (inspect)
  1354              _arguments $(__docker_arguments) \
  1355                  $opts_help \
  1356                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " \
  1357                  "($help -)1:volume:__docker_volumes" && ret=0
  1358              ;;
  1359          (ls)
  1360              _arguments $(__docker_arguments) \
  1361                  $opts_help \
  1362                  "($help)*"{-f=,--filter=}"[Provide filter values]:filter:->filter-options" \
  1363                  "($help)--format=[Pretty-print volumes using a Go template]:template: " \
  1364                  "($help -q --quiet)"{-q,--quiet}"[Only display volume names]" && ret=0
  1365              case $state in
  1366                  (filter-options)
  1367                      __docker_volume_complete_ls_filters && ret=0
  1368                      ;;
  1369              esac
  1370              ;;
  1371          (rm)
  1372              _arguments $(__docker_arguments) \
  1373                  $opts_help \
  1374                  "($help -f --force)"{-f,--force}"[Force the removal of one or more volumes]" \
  1375                  "($help -):volume:__docker_volumes" && ret=0
  1376              ;;
  1377          (help)
  1378              _arguments $(__docker_arguments) ":subcommand:__docker_volume_commands" && ret=0
  1379              ;;
  1380      esac
  1381  
  1382      return ret
  1383  }
  1384  
  1385  # EO volume
  1386  
  1387  __docker_caching_policy() {
  1388    oldp=( "$1"(Nmh+1) )     # 1 hour
  1389    (( $#oldp ))
  1390  }
  1391  
  1392  __docker_commands() {
  1393      local cache_policy
  1394  
  1395      zstyle -s ":completion:${curcontext}:" cache-policy cache_policy
  1396      if [[ -z "$cache_policy" ]]; then
  1397          zstyle ":completion:${curcontext}:" cache-policy __docker_caching_policy
  1398      fi
  1399  
  1400      if ( [[ ${+_docker_subcommands} -eq 0 ]] || _cache_invalid docker_subcommands) \
  1401          && ! _retrieve_cache docker_subcommands;
  1402      then
  1403          local -a lines
  1404          lines=(${(f)"$(_call_program commands docker 2>&1)"})
  1405          _docker_subcommands=(${${${lines[$((${lines[(i)Commands:]} + 1)),${lines[(I)    *]}]}## #}/ ##/:})
  1406          _docker_subcommands=($_docker_subcommands 'daemon:Enable daemon mode' 'help:Show help for a command')
  1407          (( $#_docker_subcommands > 2 )) && _store_cache docker_subcommands _docker_subcommands
  1408      fi
  1409      _describe -t docker-commands "docker command" _docker_subcommands
  1410  }
  1411  
  1412  __docker_subcommand() {
  1413      local -a _command_args opts_help opts_build_create_run opts_build_create_run_update opts_create_run opts_create_run_update
  1414      local expl help="--help"
  1415      integer ret=1
  1416  
  1417      opts_help=("(: -)--help[Print usage]")
  1418      opts_build_create_run=(
  1419          "($help)--cgroup-parent=[Parent cgroup for the container]:cgroup: "
  1420          "($help)--isolation=[Container isolation technology]:isolation:(default hyperv process)"
  1421          "($help)--disable-content-trust[Skip image verification]"
  1422          "($help)*--shm-size=[Size of '/dev/shm' (format is '<number><unit>')]:shm size: "
  1423          "($help)*--ulimit=[ulimit options]:ulimit: "
  1424          "($help)--userns=[Container user namespace]:user namespace:(host)"
  1425      )
  1426      opts_build_create_run_update=(
  1427          "($help -c --cpu-shares)"{-c=,--cpu-shares=}"[CPU shares (relative weight)]:CPU shares:(0 10 100 200 500 800 1000)"
  1428          "($help)--cpu-period=[Limit the CPU CFS (Completely Fair Scheduler) period]:CPU period: "
  1429          "($help)--cpu-quota=[Limit the CPU CFS (Completely Fair Scheduler) quota]:CPU quota: "
  1430          "($help)--cpuset-cpus=[CPUs in which to allow execution]:CPUs: "
  1431          "($help)--cpuset-mems=[MEMs in which to allow execution]:MEMs: "
  1432          "($help -m --memory)"{-m=,--memory=}"[Memory limit]:Memory limit: "
  1433          "($help)--memory-swap=[Total memory limit with swap]:Memory limit: "
  1434      )
  1435      opts_create_run=(
  1436          "($help -a --attach)"{-a=,--attach=}"[Attach to stdin, stdout or stderr]:device:(STDIN STDOUT STDERR)"
  1437          "($help)*--add-host=[Add a custom host-to-IP mapping]:host\:ip mapping: "
  1438          "($help)*--blkio-weight-device=[Block IO (relative device weight)]:device:Block IO weight: "
  1439          "($help)*--cap-add=[Add Linux capabilities]:capability: "
  1440          "($help)*--cap-drop=[Drop Linux capabilities]:capability: "
  1441          "($help)--cidfile=[Write the container ID to the file]:CID file:_files"
  1442          "($help)*--device=[Add a host device to the container]:device:_files"
  1443          "($help)*--device-read-bps=[Limit the read rate (bytes per second) from a device]:device:IO rate: "
  1444          "($help)*--device-read-iops=[Limit the read rate (IO per second) from a device]:device:IO rate: "
  1445          "($help)*--device-write-bps=[Limit the write rate (bytes per second) to a device]:device:IO rate: "
  1446          "($help)*--device-write-iops=[Limit the write rate (IO per second) to a device]:device:IO rate: "
  1447          "($help)*--dns=[Custom DNS servers]:DNS server: "
  1448          "($help)*--dns-opt=[Custom DNS options]:DNS option: "
  1449          "($help)*--dns-search=[Custom DNS search domains]:DNS domains: "
  1450          "($help)*"{-e=,--env=}"[Environment variables]:environment variable: "
  1451          "($help)--entrypoint=[Overwrite the default entrypoint of the image]:entry point: "
  1452          "($help)*--env-file=[Read environment variables from a file]:environment file:_files"
  1453          "($help)*--expose=[Expose a port from the container without publishing it]: "
  1454          "($help)*--group-add=[Add additional groups to run as]:group:_groups"
  1455          "($help -h --hostname)"{-h=,--hostname=}"[Container host name]:hostname:_hosts"
  1456          "($help -i --interactive)"{-i,--interactive}"[Keep stdin open even if not attached]"
  1457          "($help)--ip=[Container IPv4 address]:IPv4: "
  1458          "($help)--ip6=[Container IPv6 address]:IPv6: "
  1459          "($help)--ipc=[IPC namespace to use]:IPC namespace: "
  1460          "($help)*--link=[Add link to another container]:link:->link"
  1461          "($help)*--link-local-ip=[Add a link-local address for the container]:IPv4/IPv6: "
  1462          "($help)*"{-l=,--label=}"[Container metadata]:label: "
  1463          "($help)--log-driver=[Default driver for container logs]:logging driver:__docker_log_drivers"
  1464          "($help)*--log-opt=[Log driver specific options]:log driver options:__docker_log_options"
  1465          "($help)--mac-address=[Container MAC address]:MAC address: "
  1466          "($help)--name=[Container name]:name: "
  1467          "($help)--network=[Connect a container to a network]:network mode:(bridge none container host)"
  1468          "($help)*--network-alias=[Add network-scoped alias for the container]:alias: "
  1469          "($help)--oom-kill-disable[Disable OOM Killer]"
  1470          "($help)--oom-score-adj[Tune the host's OOM preferences for containers (accepts -1000 to 1000)]"
  1471          "($help)--pids-limit[Tune container pids limit (set -1 for unlimited)]"
  1472          "($help -P --publish-all)"{-P,--publish-all}"[Publish all exposed ports]"
  1473          "($help)*"{-p=,--publish=}"[Expose a container's port to the host]:port:_ports"
  1474          "($help)--pid=[PID namespace to use]:PID namespace:__docker_complete_pid"
  1475          "($help)--privileged[Give extended privileges to this container]"
  1476          "($help)--read-only[Mount the container's root filesystem as read only]"
  1477          "($help)*--security-opt=[Security options]:security option: "
  1478          "($help)*--sysctl=-[sysctl options]:sysctl: "
  1479          "($help -t --tty)"{-t,--tty}"[Allocate a pseudo-tty]"
  1480          "($help -u --user)"{-u=,--user=}"[Username or UID]:user:_users"
  1481          "($help)--tmpfs[mount tmpfs]"
  1482          "($help)*-v[Bind mount a volume]:volume: "
  1483          "($help)--volume-driver=[Optional volume driver for the container]:volume driver:(local)"
  1484          "($help)*--volumes-from=[Mount volumes from the specified container]:volume: "
  1485          "($help -w --workdir)"{-w=,--workdir=}"[Working directory inside the container]:directory:_directories"
  1486      )
  1487      opts_create_run_update=(
  1488          "($help)--blkio-weight=[Block IO (relative weight), between 10 and 1000]:Block IO weight:(10 100 500 1000)"
  1489          "($help)--kernel-memory=[Kernel memory limit in bytes]:Memory limit: "
  1490          "($help)--memory-reservation=[Memory soft limit]:Memory limit: "
  1491          "($help)--restart=[Restart policy]:restart policy:(no on-failure always unless-stopped)"
  1492      )
  1493      opts_attach_exec_run_start=(
  1494          "($help)--detach-keys=[Escape key sequence used to detach a container]:sequence:__docker_complete_detach_keys"
  1495      )
  1496  
  1497      case "$words[1]" in
  1498          (attach)
  1499              _arguments $(__docker_arguments) \
  1500                  $opts_help \
  1501                  $opts_attach_exec_run_start \
  1502                  "($help)--no-stdin[Do not attach stdin]" \
  1503                  "($help)--sig-proxy[Proxy all received signals to the process (non-TTY mode only)]" \
  1504                  "($help -):containers:__docker_runningcontainers" && ret=0
  1505              ;;
  1506          (build)
  1507              _arguments $(__docker_arguments) \
  1508                  $opts_help \
  1509                  $opts_build_create_run \
  1510                  $opts_build_create_run_update \
  1511                  "($help)*--build-arg[Build-time variables]:<varname>=<value>: " \
  1512                  "($help -f --file)"{-f=,--file=}"[Name of the Dockerfile]:Dockerfile:_files" \
  1513                  "($help)--force-rm[Always remove intermediate containers]" \
  1514                  "($help)*--label=[Set metadata for an image]:label=value: " \
  1515                  "($help)--no-cache[Do not use cache when building the image]" \
  1516                  "($help)--pull[Attempt to pull a newer version of the image]" \
  1517                  "($help -q --quiet)"{-q,--quiet}"[Suppress verbose build output]" \
  1518                  "($help)--rm[Remove intermediate containers after a successful build]" \
  1519                  "($help -t --tag)*"{-t=,--tag=}"[Repository, name and tag for the image]: :__docker_repositories_with_tags" \
  1520                  "($help -):path or URL:_directories" && ret=0
  1521              ;;
  1522          (commit)
  1523              _arguments $(__docker_arguments) \
  1524                  $opts_help \
  1525                  "($help -a --author)"{-a=,--author=}"[Author]:author: " \
  1526                  "($help)*"{-c=,--change=}"[Apply Dockerfile instruction to the created image]:Dockerfile:_files" \
  1527                  "($help -m --message)"{-m=,--message=}"[Commit message]:message: " \
  1528                  "($help -p --pause)"{-p,--pause}"[Pause container during commit]" \
  1529                  "($help -):container:__docker_containers" \
  1530                  "($help -): :__docker_repositories_with_tags" && ret=0
  1531              ;;
  1532          (cp)
  1533              _arguments $(__docker_arguments) \
  1534                  $opts_help \
  1535                  "($help -L --follow-link)"{-L,--follow-link}"[Always follow symbol link]" \
  1536                  "($help -)1:container:->container" \
  1537                  "($help -)2:hostpath:_files" && ret=0
  1538              case $state in
  1539                  (container)
  1540                      if compset -P "*:"; then
  1541                          _files && ret=0
  1542                      else
  1543                          __docker_containers -qS ":" && ret=0
  1544                      fi
  1545                      ;;
  1546              esac
  1547              ;;
  1548          (create)
  1549              _arguments $(__docker_arguments) \
  1550                  $opts_help \
  1551                  $opts_build_create_run \
  1552                  $opts_build_create_run_update \
  1553                  $opts_create_run \
  1554                  $opts_create_run_update \
  1555                  "($help -): :__docker_images" \
  1556                  "($help -):command: _command_names -e" \
  1557                  "($help -)*::arguments: _normal" && ret=0
  1558  
  1559              case $state in
  1560                  (link)
  1561                      if compset -P "*:"; then
  1562                          _wanted alias expl "Alias" compadd -E "" && ret=0
  1563                      else
  1564                          __docker_runningcontainers -qS ":" && ret=0
  1565                      fi
  1566                      ;;
  1567              esac
  1568  
  1569              ;;
  1570          (daemon)
  1571              _arguments $(__docker_arguments) \
  1572                  $opts_help \
  1573                  "($help)*--add-runtime=[Register an additional OCI compatible runtime]:runtime:__docker_complete_runtimes" \
  1574                  "($help)--api-cors-header=[CORS headers in the remote API]:CORS headers: " \
  1575                  "($help)*--authorization-plugin=[Authorization plugins to load]" \
  1576                  "($help -b --bridge)"{-b=,--bridge=}"[Attach containers to a network bridge]:bridge:_net_interfaces" \
  1577                  "($help)--bip=[Network bridge IP]:IP address: " \
  1578                  "($help)--cgroup-parent=[Parent cgroup for all containers]:cgroup: " \
  1579                  "($help)--config-file=[Path to daemon configuration file]:Config File:_files" \
  1580                  "($help)--containerd=[Path to containerd socket]:socket:_files -g \"*.sock\"" \
  1581                  "($help -D --debug)"{-D,--debug}"[Enable debug mode]" \
  1582                  "($help)--default-gateway[Container default gateway IPv4 address]:IPv4 address: " \
  1583                  "($help)--default-gateway-v6[Container default gateway IPv6 address]:IPv6 address: " \
  1584                  "($help)--cluster-store=[URL of the distributed storage backend]:Cluster Store:->cluster-store" \
  1585                  "($help)--cluster-advertise=[Address or interface name to advertise]:Instance to advertise (host\:port): " \
  1586                  "($help)*--cluster-store-opt=[Cluster store options]:Cluster options:->cluster-store-options" \
  1587                  "($help)*--dns=[DNS server to use]:DNS: " \
  1588                  "($help)*--dns-search=[DNS search domains to use]:DNS search: " \
  1589                  "($help)*--dns-opt=[DNS options to use]:DNS option: " \
  1590                  "($help)*--default-ulimit=[Default ulimits for containers]:ulimit: " \
  1591                  "($help)--disable-legacy-registry[Disable contacting legacy registries]" \
  1592                  "($help)*--exec-opt=[Runtime execution options]:runtime execution options: " \
  1593                  "($help)--exec-root=[Root directory for execution state files]:path:_directories" \
  1594                  "($help)--fixed-cidr=[IPv4 subnet for fixed IPs]:IPv4 subnet: " \
  1595                  "($help)--fixed-cidr-v6=[IPv6 subnet for fixed IPs]:IPv6 subnet: " \
  1596                  "($help -G --group)"{-G=,--group=}"[Group for the unix socket]:group:_groups" \
  1597                  "($help -g --graph)"{-g=,--graph=}"[Root of the Docker runtime]:path:_directories" \
  1598                  "($help -H --host)"{-H=,--host=}"[tcp://host:port to bind/connect to]:host: " \
  1599                  "($help)--icc[Enable inter-container communication]" \
  1600                  "($help)*--insecure-registry=[Enable insecure registry communication]:registry: " \
  1601                  "($help)--ip=[Default IP when binding container ports]" \
  1602                  "($help)--ip-forward[Enable net.ipv4.ip_forward]" \
  1603                  "($help)--ip-masq[Enable IP masquerading]" \
  1604                  "($help)--iptables[Enable addition of iptables rules]" \
  1605                  "($help)--ipv6[Enable IPv6 networking]" \
  1606                  "($help -l --log-level)"{-l=,--log-level=}"[Logging level]:level:(debug info warn error fatal)" \
  1607                  "($help)*--label=[Key=value labels]:label: " \
  1608                  "($help)--live-restore[Enable live restore of docker when containers are still running]" \
  1609                  "($help)--log-driver=[Default driver for container logs]:logging driver:__docker_log_drivers" \
  1610                  "($help)*--log-opt=[Default log driver options for containers]:log driver options:__docker_log_options" \
  1611                  "($help)--max-concurrent-downloads[Set the max concurrent downloads for each pull]" \
  1612                  "($help)--max-concurrent-uploads[Set the max concurrent uploads for each push]" \
  1613                  "($help)--mtu=[Network MTU]:mtu:(0 576 1420 1500 9000)" \
  1614                  "($help)--oom-score-adjust=[Set the oom_score_adj for the daemon]:oom-score:(-500)" \
  1615                  "($help -p --pidfile)"{-p=,--pidfile=}"[Path to use for daemon PID file]:PID file:_files" \
  1616                  "($help)--raw-logs[Full timestamps without ANSI coloring]" \
  1617                  "($help)*--registry-mirror=[Preferred Docker registry mirror]:registry mirror: " \
  1618                  "($help -s --storage-driver)"{-s=,--storage-driver=}"[Storage driver to use]:driver:(aufs btrfs devicemapper overlay overlay2 vfs zfs)" \
  1619                  "($help)--selinux-enabled[Enable selinux support]" \
  1620                  "($help)*--storage-opt=[Storage driver options]:storage driver options: " \
  1621                  "($help)--tls[Use TLS]" \
  1622                  "($help)--tlscacert=[Trust certs signed only by this CA]:PEM file:_files -g \"*.(pem|crt)\"" \
  1623                  "($help)--tlscert=[Path to TLS certificate file]:PEM file:_files -g \"*.(pem|crt)\"" \
  1624                  "($help)--tlskey=[Path to TLS key file]:Key file:_files -g \"*.(pem|key)\"" \
  1625                  "($help)--tlsverify[Use TLS and verify the remote]" \
  1626                  "($help)--userns-remap=[User/Group setting for user namespaces]:user\:group:->users-groups" \
  1627                  "($help)--userland-proxy[Use userland proxy for loopback traffic]" && ret=0
  1628  
  1629              case $state in
  1630                  (cluster-store)
  1631                      if compset -P '*://'; then
  1632                          _message 'host:port' && ret=0
  1633                      else
  1634                          store=('consul' 'etcd' 'zk')
  1635                          _describe -t cluster-store "Cluster Store" store -qS "://" && ret=0
  1636                      fi
  1637                      ;;
  1638                  (cluster-store-options)
  1639                      if compset -P '*='; then
  1640                          _files && ret=0
  1641                      else
  1642                          opts=('discovery.heartbeat' 'discovery.ttl' 'kv.cacertfile' 'kv.certfile' 'kv.keyfile' 'kv.path')
  1643                          _describe -t cluster-store-opts "Cluster Store Options" opts -qS "=" && ret=0
  1644                      fi
  1645                      ;;
  1646                  (users-groups)
  1647                      if compset -P '*:'; then
  1648                          _groups && ret=0
  1649                      else
  1650                          _describe -t userns-default "default Docker user management" '(default)' && ret=0
  1651                          _users && ret=0
  1652                      fi
  1653                      ;;
  1654              esac
  1655              ;;
  1656          (diff)
  1657              _arguments $(__docker_arguments) \
  1658                  $opts_help \
  1659                  "($help -)*:containers:__docker_containers" && ret=0
  1660              ;;
  1661          (events)
  1662              _arguments $(__docker_arguments) \
  1663                  $opts_help \
  1664                  "($help)*"{-f=,--filter=}"[Filter values]:filter:__docker_complete_events_filter" \
  1665                  "($help)--since=[Events created since this timestamp]:timestamp: " \
  1666                  "($help)--until=[Events created until this timestamp]:timestamp: " \
  1667                  "($help)--format=[Format the output using the given go template]:template: " && ret=0
  1668              ;;
  1669          (exec)
  1670              local state
  1671              _arguments $(__docker_arguments) \
  1672                  $opts_help \
  1673                  $opts_attach_exec_run_start \
  1674                  "($help -d --detach)"{-d,--detach}"[Detached mode: leave the container running in the background]" \
  1675                  "($help -i --interactive)"{-i,--interactive}"[Keep stdin open even if not attached]" \
  1676                  "($help)--privileged[Give extended Linux capabilities to the command]" \
  1677                  "($help -t --tty)"{-t,--tty}"[Allocate a pseudo-tty]" \
  1678                  "($help -u --user)"{-u=,--user=}"[Username or UID]:user:_users" \
  1679                  "($help -):containers:__docker_runningcontainers" \
  1680                  "($help -)*::command:->anycommand" && ret=0
  1681  
  1682              case $state in
  1683                  (anycommand)
  1684                      shift 1 words
  1685                      (( CURRENT-- ))
  1686                      _normal && ret=0
  1687                      ;;
  1688              esac
  1689              ;;
  1690          (export)
  1691              _arguments $(__docker_arguments) \
  1692                  $opts_help \
  1693                  "($help -o --output)"{-o=,--output=}"[Write to a file, instead of stdout]:output file:_files" \
  1694                  "($help -)*:containers:__docker_containers" && ret=0
  1695              ;;
  1696          (history)
  1697              _arguments $(__docker_arguments) \
  1698                  $opts_help \
  1699                  "($help -H --human)"{-H,--human}"[Print sizes and dates in human readable format]" \
  1700                  "($help)--no-trunc[Do not truncate output]" \
  1701                  "($help -q --quiet)"{-q,--quiet}"[Only show numeric IDs]" \
  1702                  "($help -)*: :__docker_images" && ret=0
  1703              ;;
  1704          (images)
  1705              _arguments $(__docker_arguments) \
  1706                  $opts_help \
  1707                  "($help -a --all)"{-a,--all}"[Show all images]" \
  1708                  "($help)--digests[Show digests]" \
  1709                  "($help)*"{-f=,--filter=}"[Filter values]:filter:->filter-options" \
  1710                  "($help)--format=[Pretty-print images using a Go template]:template: " \
  1711                  "($help)--no-trunc[Do not truncate output]" \
  1712                  "($help -q --quiet)"{-q,--quiet}"[Only show numeric IDs]" \
  1713                  "($help -): :__docker_repositories" && ret=0
  1714  
  1715              case $state in
  1716                  (filter-options)
  1717                      __docker_complete_images_filters && ret=0
  1718                      ;;
  1719              esac
  1720              ;;
  1721          (import)
  1722              _arguments $(__docker_arguments) \
  1723                  $opts_help \
  1724                  "($help)*"{-c=,--change=}"[Apply Dockerfile instruction to the created image]:Dockerfile:_files" \
  1725                  "($help -m --message)"{-m=,--message=}"[Commit message for imported image]:message: " \
  1726                  "($help -):URL:(- http:// file://)" \
  1727                  "($help -): :__docker_repositories_with_tags" && ret=0
  1728              ;;
  1729          (info|version)
  1730              _arguments $(__docker_arguments) \
  1731                  $opts_help \
  1732                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " && ret=0
  1733              ;;
  1734          (inspect)
  1735              local state
  1736              _arguments $(__docker_arguments) \
  1737                  $opts_help \
  1738                  "($help -f --format)"{-f=,--format=}"[Format the output using the given go template]:template: " \
  1739                  "($help -s --size)"{-s,--size}"[Display total file sizes if the type is container]" \
  1740                  "($help)--type=[Return JSON for specified type]:type:(image container)" \
  1741                  "($help -)*: :->values" && ret=0
  1742  
  1743              case $state in
  1744                  (values)
  1745                      if [[ ${words[(r)--type=container]} == --type=container ]]; then
  1746                          __docker_containers && ret=0
  1747                      elif [[ ${words[(r)--type=image]} == --type=image ]]; then
  1748                          __docker_images && ret=0
  1749                      else
  1750                          __docker_images && __docker_containers && ret=0
  1751                      fi
  1752                      ;;
  1753              esac
  1754              ;;
  1755          (kill)
  1756              _arguments $(__docker_arguments) \
  1757                  $opts_help \
  1758                  "($help -s --signal)"{-s=,--signal=}"[Signal to send]:signal:_signals" \
  1759                  "($help -)*:containers:__docker_runningcontainers" && ret=0
  1760              ;;
  1761          (load)
  1762              _arguments $(__docker_arguments) \
  1763                  $opts_help \
  1764                  "($help -i --input)"{-i=,--input=}"[Read from tar archive file]:archive file:_files -g \"*.((tar|TAR)(.gz|.GZ|.Z|.bz2|.lzma|.xz|)|(tbz|tgz|txz))(-.)\"" \
  1765                  "($help -q --quiet)"{-q,--quiet}"[Suppress the load output]" && ret=0
  1766              ;;
  1767          (login)
  1768              _arguments $(__docker_arguments) \
  1769                  $opts_help \
  1770                  "($help -p --password)"{-p=,--password=}"[Password]:password: " \
  1771                  "($help -u --user)"{-u=,--user=}"[Username]:username: " \
  1772                  "($help -)1:server: " && ret=0
  1773              ;;
  1774          (logout)
  1775              _arguments $(__docker_arguments) \
  1776                  $opts_help \
  1777                  "($help -)1:server: " && ret=0
  1778              ;;
  1779          (logs)
  1780              _arguments $(__docker_arguments) \
  1781                  $opts_help \
  1782                  "($help)--details[Show extra details provided to logs]" \
  1783                  "($help -f --follow)"{-f,--follow}"[Follow log output]" \
  1784                  "($help -s --since)"{-s=,--since=}"[Show logs since this timestamp]:timestamp: " \
  1785                  "($help -t --timestamps)"{-t,--timestamps}"[Show timestamps]" \
  1786                  "($help)--tail=[Output the last K lines]:lines:(1 10 20 50 all)" \
  1787                  "($help -)*:containers:__docker_containers" && ret=0
  1788              ;;
  1789          (network)
  1790              local curcontext="$curcontext" state
  1791              _arguments $(__docker_arguments) \
  1792                  $opts_help \
  1793                  "($help -): :->command" \
  1794                  "($help -)*:: :->option-or-argument" && ret=0
  1795  
  1796              case $state in
  1797                  (command)
  1798                      __docker_network_commands && ret=0
  1799                      ;;
  1800                  (option-or-argument)
  1801                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  1802                      __docker_network_subcommand && ret=0
  1803                      ;;
  1804              esac
  1805              ;;
  1806          (node)
  1807              local curcontext="$curcontext" state
  1808              _arguments $(__docker_arguments) \
  1809                  $opts_help \
  1810                  "($help -): :->command" \
  1811                  "($help -)*:: :->option-or-argument" && ret=0
  1812  
  1813              case $state in
  1814                  (command)
  1815                      __docker_node_commands && ret=0
  1816                      ;;
  1817                  (option-or-argument)
  1818                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  1819                      __docker_node_subcommand && ret=0
  1820                      ;;
  1821              esac
  1822              ;;
  1823          (pause|unpause)
  1824              _arguments $(__docker_arguments) \
  1825                  $opts_help \
  1826                  "($help -)*:containers:__docker_runningcontainers" && ret=0
  1827              ;;
  1828          (plugin)
  1829              local curcontext="$curcontext" state
  1830              _arguments $(__docker_arguments) \
  1831                  $opts_help \
  1832                  "($help -): :->command" \
  1833                  "($help -)*:: :->option-or-argument" && ret=0
  1834  
  1835              case $state in
  1836                  (command)
  1837                      __docker_plugin_commands && ret=0
  1838                      ;;
  1839                  (option-or-argument)
  1840                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  1841                      __docker_plugin_subcommand && ret=0
  1842                      ;;
  1843              esac
  1844              ;;
  1845          (port)
  1846              _arguments $(__docker_arguments) \
  1847                  $opts_help \
  1848                  "($help -)1:containers:__docker_runningcontainers" \
  1849                  "($help -)2:port:_ports" && ret=0
  1850              ;;
  1851          (ps)
  1852              _arguments $(__docker_arguments) \
  1853                  $opts_help \
  1854                  "($help -a --all)"{-a,--all}"[Show all containers]" \
  1855                  "($help)--before=[Show only container created before...]:containers:__docker_containers" \
  1856                  "($help)*"{-f=,--filter=}"[Filter values]:filter:__docker_complete_ps_filters" \
  1857                  "($help)--format=[Pretty-print containers using a Go template]:template: " \
  1858                  "($help -l --latest)"{-l,--latest}"[Show only the latest created container]" \
  1859                  "($help -n --last)"{-n=,--last=}"[Show n last created containers (includes all states)]:n:(1 5 10 25 50)" \
  1860                  "($help)--no-trunc[Do not truncate output]" \
  1861                  "($help -q --quiet)"{-q,--quiet}"[Only show numeric IDs]" \
  1862                  "($help -s --size)"{-s,--size}"[Display total file sizes]" \
  1863                  "($help)--since=[Show only containers created since...]:containers:__docker_containers" && ret=0
  1864              ;;
  1865          (pull)
  1866              _arguments $(__docker_arguments) \
  1867                  $opts_help \
  1868                  "($help -a --all-tags)"{-a,--all-tags}"[Download all tagged images]" \
  1869                  "($help)--disable-content-trust[Skip image verification]" \
  1870                  "($help -):name:__docker_search" && ret=0
  1871              ;;
  1872          (push)
  1873              _arguments $(__docker_arguments) \
  1874                  $opts_help \
  1875                  "($help)--disable-content-trust[Skip image signing]" \
  1876                  "($help -): :__docker_images" && ret=0
  1877              ;;
  1878          (rename)
  1879              _arguments $(__docker_arguments) \
  1880                  $opts_help \
  1881                  "($help -):old name:__docker_containers" \
  1882                  "($help -):new name: " && ret=0
  1883              ;;
  1884          (restart|stop)
  1885              _arguments $(__docker_arguments) \
  1886                  $opts_help \
  1887                  "($help -t --time)"{-t=,--time=}"[Number of seconds to try to stop for before killing the container]:seconds to before killing:(1 5 10 30 60)" \
  1888                  "($help -)*:containers:__docker_runningcontainers" && ret=0
  1889              ;;
  1890          (rm)
  1891              _arguments $(__docker_arguments) \
  1892                  $opts_help \
  1893                  "($help -f --force)"{-f,--force}"[Force removal]" \
  1894                  "($help -l --link)"{-l,--link}"[Remove the specified link and not the underlying container]" \
  1895                  "($help -v --volumes)"{-v,--volumes}"[Remove the volumes associated to the container]" \
  1896                  "($help -)*:containers:->values" && ret=0
  1897              case $state in
  1898                  (values)
  1899                      if [[ ${words[(r)-f]} == -f || ${words[(r)--force]} == --force ]]; then
  1900                          __docker_containers && ret=0
  1901                      else
  1902                          __docker_stoppedcontainers && ret=0
  1903                      fi
  1904                      ;;
  1905              esac
  1906              ;;
  1907          (rmi)
  1908              _arguments $(__docker_arguments) \
  1909                  $opts_help \
  1910                  "($help -f --force)"{-f,--force}"[Force removal]" \
  1911                  "($help)--no-prune[Do not delete untagged parents]" \
  1912                  "($help -)*: :__docker_images" && ret=0
  1913              ;;
  1914          (run)
  1915              _arguments $(__docker_arguments) \
  1916                  $opts_help \
  1917                  $opts_build_create_run \
  1918                  $opts_build_create_run_update \
  1919                  $opts_create_run \
  1920                  $opts_create_run_update \
  1921                  $opts_attach_exec_run_start \
  1922                  "($help -d --detach)"{-d,--detach}"[Detached mode: leave the container running in the background]" \
  1923                  "($help)--health-cmd=[Command to run to check health]:command: " \
  1924                  "($help)--health-interval=[Time between running the check]:time: " \
  1925                  "($help)--health-retries=[Consecutive failures needed to report unhealthy]:retries:(1 2 3 4 5)" \
  1926                  "($help)--health-timeout=[Maximum time to allow one check to run]:time: " \
  1927                  "($help)--no-healthcheck[Disable any container-specified HEALTHCHECK]" \
  1928                  "($help)--rm[Remove intermediate containers when it exits]" \
  1929                  "($help)--runtime=[Name of the runtime to be used for that container]:runtime:__docker_complete_runtimes" \
  1930                  "($help)--sig-proxy[Proxy all received signals to the process (non-TTY mode only)]" \
  1931                  "($help)--stop-signal=[Signal to kill a container]:signal:_signals" \
  1932                  "($help)--storage-opt=[Storage driver options for the container]:storage options:->storage-opt" \
  1933                  "($help -): :__docker_images" \
  1934                  "($help -):command: _command_names -e" \
  1935                  "($help -)*::arguments: _normal" && ret=0
  1936  
  1937              case $state in
  1938                  (link)
  1939                      if compset -P "*:"; then
  1940                          _wanted alias expl "Alias" compadd -E "" && ret=0
  1941                      else
  1942                          __docker_runningcontainers -qS ":" && ret=0
  1943                      fi
  1944                      ;;
  1945                  (storage-opt)
  1946                      if compset -P "*="; then
  1947                          _message "value" && ret=0
  1948                      else
  1949                          opts=('size')
  1950                          _describe -t filter-opts "storage options" opts -qS "=" && ret=0
  1951                      fi
  1952                      ;;
  1953              esac
  1954  
  1955              ;;
  1956          (save)
  1957              _arguments $(__docker_arguments) \
  1958                  $opts_help \
  1959                  "($help -o --output)"{-o=,--output=}"[Write to file]:file:_files" \
  1960                  "($help -)*: :__docker_images" && ret=0
  1961              ;;
  1962          (search)
  1963              _arguments $(__docker_arguments) \
  1964                  $opts_help \
  1965                  "($help)*"{-f=,--filter=}"[Filter values]:filter:->filter-options" \
  1966                  "($help)--limit=[Maximum returned search results]:limit:(1 5 10 25 50)" \
  1967                  "($help)--no-trunc[Do not truncate output]" \
  1968                  "($help -):term: " && ret=0
  1969  
  1970              case $state in
  1971                  (filter-options)
  1972                      __docker_complete_search_filters && ret=0
  1973                      ;;
  1974              esac
  1975              ;;
  1976          (service)
  1977              local curcontext="$curcontext" state
  1978              _arguments $(__docker_arguments) \
  1979                  $opts_help \
  1980                  "($help -): :->command" \
  1981                  "($help -)*:: :->option-or-argument" && ret=0
  1982  
  1983              case $state in
  1984                  (command)
  1985                      __docker_service_commands && ret=0
  1986                      ;;
  1987                  (option-or-argument)
  1988                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  1989                      __docker_service_subcommand && ret=0
  1990                      ;;
  1991              esac
  1992              ;;
  1993          (start)
  1994              _arguments $(__docker_arguments) \
  1995                  $opts_help \
  1996                  $opts_attach_exec_run_start \
  1997                  "($help -a --attach)"{-a,--attach}"[Attach container's stdout/stderr and forward all signals]" \
  1998                  "($help -i --interactive)"{-i,--interactive}"[Attach container's stding]" \
  1999                  "($help -)*:containers:__docker_stoppedcontainers" && ret=0
  2000              ;;
  2001          (stats)
  2002              _arguments $(__docker_arguments) \
  2003                  $opts_help \
  2004                  "($help -a --all)"{-a,--all}"[Show all containers (default shows just running)]" \
  2005                  "($help)--format=[Pretty-print images using a Go template]:template: " \
  2006                  "($help)--no-stream[Disable streaming stats and only pull the first result]" \
  2007                  "($help -)*:containers:__docker_runningcontainers" && ret=0
  2008              ;;
  2009          (swarm)
  2010              local curcontext="$curcontext" state
  2011              _arguments $(__docker_arguments) \
  2012                  $opts_help \
  2013                  "($help -): :->command" \
  2014                  "($help -)*:: :->option-or-argument" && ret=0
  2015  
  2016              case $state in
  2017                  (command)
  2018                      __docker_swarm_commands && ret=0
  2019                      ;;
  2020                  (option-or-argument)
  2021                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  2022                      __docker_swarm_subcommand && ret=0
  2023                      ;;
  2024              esac
  2025              ;;
  2026          (tag)
  2027              _arguments $(__docker_arguments) \
  2028                  $opts_help \
  2029                  "($help -):source:__docker_images"\
  2030                  "($help -):destination:__docker_repositories_with_tags" && ret=0
  2031              ;;
  2032          (top)
  2033              _arguments $(__docker_arguments) \
  2034                  $opts_help \
  2035                  "($help -)1:containers:__docker_runningcontainers" \
  2036                  "($help -)*:: :->ps-arguments" && ret=0
  2037              case $state in
  2038                  (ps-arguments)
  2039                      _ps && ret=0
  2040                      ;;
  2041              esac
  2042  
  2043              ;;
  2044          (update)
  2045              _arguments $(__docker_arguments) \
  2046                  $opts_help \
  2047                  $opts_create_run_update \
  2048                  $opts_build_create_run_update \
  2049                  "($help -)*: :->values" && ret=0
  2050  
  2051              case $state in
  2052                  (values)
  2053                      if [[ ${words[(r)--kernel-memory*]} = (--kernel-memory*) ]]; then
  2054                          __docker_stoppedcontainers && ret=0
  2055                      else
  2056                          __docker_containers && ret=0
  2057                      fi
  2058                      ;;
  2059              esac
  2060              ;;
  2061          (volume)
  2062              local curcontext="$curcontext" state
  2063              _arguments $(__docker_arguments) \
  2064                  $opts_help \
  2065                  "($help -): :->command" \
  2066                  "($help -)*:: :->option-or-argument" && ret=0
  2067  
  2068              case $state in
  2069                  (command)
  2070                      __docker_volume_commands && ret=0
  2071                      ;;
  2072                  (option-or-argument)
  2073                      curcontext=${curcontext%:*:*}:docker-${words[-1]}:
  2074                      __docker_volume_subcommand && ret=0
  2075                      ;;
  2076              esac
  2077              ;;
  2078          (wait)
  2079              _arguments $(__docker_arguments) \
  2080                  $opts_help \
  2081                  "($help -)*:containers:__docker_runningcontainers" && ret=0
  2082              ;;
  2083          (help)
  2084              _arguments $(__docker_arguments) ":subcommand:__docker_commands" && ret=0
  2085              ;;
  2086      esac
  2087  
  2088      return ret
  2089  }
  2090  
  2091  _docker() {
  2092      # Support for subservices, which allows for `compdef _docker docker-shell=_docker_containers`.
  2093      # Based on /usr/share/zsh/functions/Completion/Unix/_git without support for `ret`.
  2094      if [[ $service != docker ]]; then
  2095          _call_function - _$service
  2096          return
  2097      fi
  2098  
  2099      local curcontext="$curcontext" state line help="-h --help"
  2100      integer ret=1
  2101      typeset -A opt_args
  2102  
  2103      _arguments $(__docker_arguments) -C \
  2104          "(: -)"{-h,--help}"[Print usage]" \
  2105          "($help)--config[Location of client config files]:path:_directories" \
  2106          "($help -D --debug)"{-D,--debug}"[Enable debug mode]" \
  2107          "($help -H --host)"{-H=,--host=}"[tcp://host:port to bind/connect to]:host: " \
  2108          "($help -l --log-level)"{-l=,--log-level=}"[Logging level]:level:(debug info warn error fatal)" \
  2109          "($help)--tls[Use TLS]" \
  2110          "($help)--tlscacert=[Trust certs signed only by this CA]:PEM file:_files -g "*.(pem|crt)"" \
  2111          "($help)--tlscert=[Path to TLS certificate file]:PEM file:_files -g "*.(pem|crt)"" \
  2112          "($help)--tlskey=[Path to TLS key file]:Key file:_files -g "*.(pem|key)"" \
  2113          "($help)--tlsverify[Use TLS and verify the remote]" \
  2114          "($help)--userland-proxy[Use userland proxy for loopback traffic]" \
  2115          "($help -v --version)"{-v,--version}"[Print version information and quit]" \
  2116          "($help -): :->command" \
  2117          "($help -)*:: :->option-or-argument" && ret=0
  2118  
  2119      local host=${opt_args[-H]}${opt_args[--host]}
  2120      local config=${opt_args[--config]}
  2121      local docker_options="${host:+--host $host} ${config:+--config $config}"
  2122  
  2123      case $state in
  2124          (command)
  2125              __docker_commands && ret=0
  2126              ;;
  2127          (option-or-argument)
  2128              curcontext=${curcontext%:*:*}:docker-$words[1]:
  2129              __docker_subcommand && ret=0
  2130              ;;
  2131      esac
  2132  
  2133      return ret
  2134  }
  2135  
  2136  _dockerd() {
  2137      integer ret=1
  2138      words[1]='daemon'
  2139      __docker_subcommand && ret=0
  2140      return ret
  2141  }
  2142  
  2143  _docker "$@"
  2144  
  2145  # Local Variables:
  2146  # mode: Shell-Script
  2147  # sh-indentation: 4
  2148  # indent-tabs-mode: nil
  2149  # sh-basic-offset: 4
  2150  # End:
  2151  # vim: ft=zsh sw=4 ts=4 et